mirror of
https://github.com/eza-community/eza
synced 2024-10-14 20:03:50 +00:00
06c9b4f74a
Adds the tool convco to the flake, allowing eza hackers to run `convco commit`, giving a guided flow for creating conventional commits. Refs: 149 Signed-off-by: Christina Sørensen <christina@cafkafk.com>
87 lines
2.3 KiB
Nix
87 lines
2.3 KiB
Nix
{
|
|
description = "The EZA flake for developing and releasing (soon)";
|
|
|
|
inputs = {
|
|
flake-utils.url = "github:numtide/flake-utils";
|
|
naersk.url = "github:nix-community/naersk";
|
|
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
|
|
treefmt-nix.url = "github:numtide/treefmt-nix";
|
|
rust-overlay.url = "github:oxalica/rust-overlay";
|
|
};
|
|
|
|
outputs = {
|
|
self,
|
|
flake-utils,
|
|
naersk,
|
|
nixpkgs,
|
|
treefmt-nix,
|
|
rust-overlay,
|
|
}:
|
|
flake-utils.lib.eachDefaultSystem (
|
|
system: let
|
|
overlays = [(import rust-overlay)];
|
|
|
|
pkgs = (import nixpkgs) {
|
|
inherit system overlays;
|
|
};
|
|
|
|
toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
|
|
|
|
naersk' = pkgs.callPackage naersk {
|
|
cargo = toolchain;
|
|
rustc = toolchain;
|
|
clippy = toolchain;
|
|
};
|
|
|
|
treefmtEval = treefmt-nix.lib.evalModule pkgs ./treefmt.nix;
|
|
buildInputs = with pkgs; lib.optionals stdenv.isDarwin [libiconv darwin.apple_sdk.frameworks.Security];
|
|
in rec {
|
|
# For `nix fmt`
|
|
formatter = treefmtEval.config.build.wrapper;
|
|
|
|
packages = {
|
|
# For `nix build` & `nix run`:
|
|
default = naersk'.buildPackage {
|
|
src = ./.;
|
|
doCheck = true; # run `cargo test` on build
|
|
inherit buildInputs;
|
|
};
|
|
|
|
# Run `nix build .#check` to check code
|
|
check = naersk'.buildPackage {
|
|
src = ./.;
|
|
mode = "check";
|
|
inherit buildInputs;
|
|
};
|
|
|
|
# Run `nix build .#test` to run tests
|
|
test = naersk'.buildPackage {
|
|
src = ./.;
|
|
mode = "test";
|
|
inherit buildInputs;
|
|
};
|
|
|
|
# Run `nix build .#clippy` to lint code
|
|
clippy = naersk'.buildPackage {
|
|
src = ./.;
|
|
mode = "clippy";
|
|
inherit buildInputs;
|
|
};
|
|
};
|
|
|
|
# For `nix develop`:
|
|
devShells.default = pkgs.mkShell {
|
|
nativeBuildInputs = with pkgs; [ toolchain just pandoc vhs convco ];
|
|
};
|
|
|
|
# for `nix flake check`
|
|
checks = {
|
|
formatting = treefmtEval.config.build.check self;
|
|
build = packages.check;
|
|
test = packages.test;
|
|
lint = packages.clippy;
|
|
};
|
|
}
|
|
);
|
|
}
|