mirror of
https://gitlab.freedesktop.org/wayland/weston
synced 2024-09-06 18:05:39 +00:00
292aaf9308
remoting-plugin.c calls things like g_error_free() and g_object_set(), so it needs to link glib-2.0 and gobject-2.0 explicitly, instead of relying on GStreamer pkg-config bringing them in. Signed-off-by: Pekka Paalanen <pekka.paalanen@collabora.com>
33 lines
967 B
Meson
33 lines
967 B
Meson
if get_option('remoting')
|
|
user_hint = 'If you rather not build this, set "remoting=false".'
|
|
|
|
if not get_option('backend-drm')
|
|
error('Attempting to build the remoting plugin without the required DRM backend. ' + user_hint)
|
|
endif
|
|
|
|
depnames = [
|
|
'gstreamer-1.0', 'gstreamer-allocators-1.0',
|
|
'gstreamer-app-1.0', 'gstreamer-video-1.0',
|
|
'gobject-2.0', 'glib-2.0'
|
|
]
|
|
deps_remoting = [ dep_libweston ]
|
|
foreach depname : depnames
|
|
dep = dependency(depname, required: false)
|
|
if not dep.found()
|
|
error('Remoting plugin requires @0@ which was not found. '.format(depname) + user_hint)
|
|
endif
|
|
deps_remoting += dep
|
|
endforeach
|
|
|
|
plugin_remoting = shared_library(
|
|
'remoting-plugin',
|
|
'remoting-plugin.c',
|
|
include_directories: include_directories('..', '../shared'),
|
|
dependencies: deps_remoting,
|
|
name_prefix: '',
|
|
install: true,
|
|
install_dir: dir_module_libweston
|
|
)
|
|
env_modmap += 'remoting-plugin.so=@0@;'.format(plugin_remoting.full_path())
|
|
endif
|