mirror of
https://gitlab.freedesktop.org/wayland/weston
synced 2024-09-06 18:05:39 +00:00
d8d9f5e6e1
Some clients like the mpv video player now request the xdg_shell protocol so these will fail if the compositor only provides the xdg_shell_unstable_v6 protocol. Compositors like mir and gnome provide both protocols. The two protocols are very similar therefore the code in xdg-shell-v6.c has been refactored to work with the new xdg_shell protocol and now resides in xdg-shell.c. Pekka: - split the patch - fix continued line alignment Daniel - allow anchor_rect to initially have zero dimensions - account for get_popup allowing NULL parent surface Signed-off-by: Pekka Paalanen <pekka.paalanen@collabora.com> Signed-off-by: Daniel Stone <daniels@collabora.com>
78 lines
2.4 KiB
Meson
78 lines
2.4 KiB
Meson
dep_scanner = dependency('wayland-scanner', native: true)
|
|
prog_scanner = find_program(dep_scanner.get_pkgconfig_variable('wayland_scanner'))
|
|
|
|
# XXX: For minor version 2 of zwp_linux_explicit_synchronization_v1, we
|
|
# actually need a development version after 1.17, but there is no way to
|
|
# express such a requirement at the moment.
|
|
dep_wp = dependency('wayland-protocols', version: '>= 1.17')
|
|
dir_wp_base = dep_wp.get_pkgconfig_variable('pkgdatadir')
|
|
|
|
install_data(
|
|
[
|
|
'weston-debug.xml',
|
|
],
|
|
install_dir: join_paths(dir_data, dir_protocol_libweston)
|
|
)
|
|
|
|
generated_protocols = [
|
|
[ 'input-method', 'v1' ],
|
|
[ 'input-timestamps', 'v1' ],
|
|
[ 'ivi-application', 'internal' ],
|
|
[ 'ivi-hmi-controller', 'internal' ],
|
|
[ 'fullscreen-shell', 'v1' ],
|
|
[ 'linux-dmabuf', 'v1' ],
|
|
[ 'linux-explicit-synchronization', 'v1' ],
|
|
[ 'presentation-time', 'stable' ],
|
|
[ 'pointer-constraints', 'v1' ],
|
|
[ 'relative-pointer', 'v1' ],
|
|
[ 'tablet', 'v2' ],
|
|
[ 'text-cursor-position', 'internal' ],
|
|
[ 'text-input', 'v1' ],
|
|
[ 'viewporter', 'stable' ],
|
|
[ 'weston-debug', 'internal' ],
|
|
[ 'weston-desktop-shell', 'internal' ],
|
|
[ 'weston-screenshooter', 'internal' ],
|
|
[ 'weston-test', 'internal' ],
|
|
[ 'weston-touch-calibration', 'internal' ],
|
|
[ 'xdg-output', 'v1' ],
|
|
[ 'xdg-shell', 'v6' ],
|
|
[ 'xdg-shell', 'stable' ],
|
|
]
|
|
|
|
foreach proto: generated_protocols
|
|
proto_name = proto[0]
|
|
if proto[1] == 'internal'
|
|
base_file = proto_name
|
|
xml_path = '@0@.xml'.format(proto_name)
|
|
elif proto[1] == 'stable'
|
|
base_file = proto_name
|
|
xml_path = '@0@/stable/@1@/@1@.xml'.format(dir_wp_base, base_file)
|
|
else
|
|
base_file = '@0@-unstable-@1@'.format(proto_name, proto[1])
|
|
xml_path = '@0@/unstable/@1@/@2@.xml'.format(dir_wp_base, proto_name, base_file)
|
|
endif
|
|
|
|
foreach output_type: [ 'client-header', 'server-header', 'private-code' ]
|
|
if output_type == 'client-header'
|
|
output_file = '@0@-client-protocol.h'.format(base_file)
|
|
elif output_type == 'server-header'
|
|
output_file = '@0@-server-protocol.h'.format(base_file)
|
|
else
|
|
output_file = '@0@-protocol.c'.format(base_file)
|
|
if dep_scanner.version().version_compare('< 1.14.91')
|
|
output_type = 'code'
|
|
endif
|
|
endif
|
|
|
|
var_name = output_file.underscorify()
|
|
target = custom_target(
|
|
'@0@ @1@'.format(base_file, output_type),
|
|
command: [ prog_scanner, output_type, '@INPUT@', '@OUTPUT@' ],
|
|
input: xml_path,
|
|
output: output_file,
|
|
)
|
|
|
|
set_variable(var_name, target)
|
|
endforeach
|
|
endforeach
|