mirror of
https://gitlab.freedesktop.org/wayland/weston
synced 2024-07-21 10:44:25 +00:00
49d6532254
Avoid duplication of atom retrieval. This is particuarly useful if one would one to reuse atom retrival in other parts, like tests. Signed-off-by: Marius Vlad <marius.vlad@collabora.com> Suggested-by: Daniel Stone <daniel.stone@collabora.com>
52 lines
1.1 KiB
Meson
52 lines
1.1 KiB
Meson
if not get_option('xwayland')
|
|
subdir_done()
|
|
endif
|
|
|
|
xwayland_dep = dependency('xwayland', required: false)
|
|
if xwayland_dep.found()
|
|
if xwayland_dep.get_pkgconfig_variable('have_listenfd') == 'true'
|
|
config_h.set('HAVE_XWAYLAND_LISTENFD', '1')
|
|
endif
|
|
endif
|
|
|
|
srcs_xwayland = [
|
|
'launcher.c',
|
|
'window-manager.c',
|
|
'selection.c',
|
|
'dnd.c',
|
|
'hash.c',
|
|
]
|
|
|
|
dep_names_xwayland = [
|
|
'xcb',
|
|
'xcb-composite',
|
|
'xcb-shape',
|
|
'xcb-xfixes',
|
|
'xcursor',
|
|
'cairo-xcb',
|
|
]
|
|
|
|
deps_xwayland = [ dep_libweston_public, dep_xcb_xwayland ]
|
|
|
|
foreach name : dep_names_xwayland
|
|
d = dependency(name, required: false)
|
|
if not d.found()
|
|
error('xwayland requires @0@ which was not found. Or, you can use \'-Dxwayland=false\'.'.format(name))
|
|
endif
|
|
deps_xwayland += d
|
|
endforeach
|
|
|
|
plugin_xwayland = shared_library(
|
|
'xwayland',
|
|
srcs_xwayland,
|
|
link_with: lib_cairo_shared,
|
|
include_directories: common_inc,
|
|
dependencies: deps_xwayland,
|
|
name_prefix: '',
|
|
install: true,
|
|
install_dir: dir_module_libweston
|
|
)
|
|
env_modmap += 'xwayland.so=@0@;'.format(plugin_xwayland.full_path())
|
|
|
|
install_headers(xwayland_api_h, subdir: dir_include_libweston_install)
|