mirror of
https://gitlab.freedesktop.org/wayland/weston
synced 2024-07-21 10:44:25 +00:00
e1c4133836
This is becausee619a65b09, 'libweston: move gl-borders code into helper lib' and6293ab1f90, 'libweston, shared: Move out weston_shell_get_binding_modifier' moved things out of libweston, and libweston implicitly depends on xkbcommon. Rather than just depending on dep_xkbcommon use the deps_for_libweston_users which includes some other dependencies as well. Had to move it out of libweston/meson.build and include it in the main meson.build as libweston/meson.build would have a circular dependency on libweston/meson.build file. This fixes the following build issue: [ 5s] FAILED: libweston/libgl-borders.a.p/gl-borders.c.o [ 5s] cc -Ilibweston/libgl-borders.a.p -Ilibweston -I../libweston -I. -I.. -Iinclude -I../include -I/usr/include/wayland -I/usr/include/pixman-1 -I/usr/include/cairo -I/usr/include/libpng16 -I/usr/include/freetype2 -I/usr/include/webp -fdiagnostics-color=always -D_FILE_OFFSET_BITS=64 -Wall -Winvalid-pch -Wextra -Wpedantic -std=gnu99 -Wmissing-prototypes -Wno-unused-parameter -Wno-shift-negative-value -Wno-missing-field-initializers -Wno-pedantic -Wundef -fvisibility=hidden -O2 -Wall -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=3 -fstack-protector-strong -funwind-tables -fasynchronous-unwind-tables -fstack-clash-protection -Werror=return-type -flto=auto -g -fPIC -MD -MQ libweston/libgl-borders.a.p/gl-borders.c.o -MF libweston/libgl-borders.a.p/gl-borders.c.o.d -o libweston/libgl-borders.a.p/gl-borders.c.o -c ../libweston/gl-borders.c [ 5s] In file included from ../libweston/renderer-gl/gl-renderer.h:32, [ 5s] from ../libweston/gl-borders.h:28, [ 5s] from ../libweston/gl-borders.c:31: [ 5s] ../include/libweston/libweston.h:39:10: fatal error: xkbcommon/xkbcommon.h: No such file or directory [ 4s] FAILED: shared/libshared.a.p/config-parser.c.o [ 4s] cc -Ishared/libshared.a.p -Ishared -I../shared -I. -I.. -Iinclude -I../include -I/usr/include/wayland -I/usr/include/pixman-1 -fdiagnostics-color=always -D_FILE_OFFSET_BITS=64 -Wall -Winvalid-pch -Wextra -Wpedantic -std=gnu99 -Wmissing-prototypes -Wno-unused-parameter -Wno-shift-negative-value -Wno-missing-field-initializers -Wno-pedantic -Wundef -fvisibility=hidden -O2 -Wall -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=3 -fstack-protector-strong -funwind-tables -fasynchronous-unwind-tables -fstack-clash-protection -Werror=return-type -flto=auto -g -fPIC -MD -MQ shared/libshared.a.p/config-parser.c.o -MF shared/libshared.a.p/config-parser.c.o.d -o shared/libshared.a.p/config-parser.c.o -c ../shared/config-parser.c [ 4s] In file included from ../shared/config-parser.c:44: [ 4s] ../include/libweston/libweston.h:39:10: fatal error: xkbcommon/xkbcommon.h: No such file or directory Reported-by: Jan Engelhardt <jengelh@inai.de> Signed-off-by: Jan Engelhardt <jengelh@inai.de> Signed-off-by: Marius Vlad <marius.vlad@collabora.com>
109 lines
2.6 KiB
Meson
109 lines
2.6 KiB
Meson
srcs_libshared = [
|
|
'config-parser.c',
|
|
'option-parser.c',
|
|
'signal.c',
|
|
'file-util.c',
|
|
'os-compatibility.c',
|
|
'process-util.c',
|
|
'hash.c',
|
|
]
|
|
deps_libshared = [dep_wayland_client, dep_wayland_server,
|
|
dep_pixman, deps_for_libweston_users]
|
|
|
|
lib_libshared = static_library(
|
|
'shared',
|
|
srcs_libshared,
|
|
include_directories: common_inc,
|
|
dependencies: deps_libshared,
|
|
pic: true,
|
|
install: false
|
|
)
|
|
dep_libshared = declare_dependency(
|
|
link_with: lib_libshared,
|
|
include_directories: public_inc,
|
|
dependencies: deps_libshared
|
|
)
|
|
|
|
xcb_dep = dependency('xcb', required: false)
|
|
|
|
xcb_xwayland_srcs = [
|
|
'xcb-xwayland.c',
|
|
]
|
|
|
|
lib_xcb_xwayland = static_library(
|
|
'xcb-xwayland',
|
|
xcb_xwayland_srcs,
|
|
include_directories: common_inc,
|
|
dependencies: [ xcb_dep ],
|
|
install: false,
|
|
build_by_default: false,
|
|
)
|
|
|
|
dep_xcb_xwayland = declare_dependency(
|
|
link_with: lib_xcb_xwayland,
|
|
include_directories: public_inc,
|
|
)
|
|
|
|
srcs_cairo_shared = [
|
|
'image-loader.c',
|
|
'cairo-util.c',
|
|
'frame.c',
|
|
]
|
|
|
|
deps_cairo_shared = [
|
|
dep_libshared,
|
|
dependency('cairo'),
|
|
dependency('libpng'),
|
|
dep_pixman,
|
|
dep_libm,
|
|
]
|
|
|
|
dep_pango = dependency('pango', required: false)
|
|
dep_pangocairo = dependency('pangocairo', required: false)
|
|
dep_fontconfig = dependency('fontconfig', required: false)
|
|
dep_glib = dependency('glib-2.0', version: '>= 2.36', required: false)
|
|
|
|
if dep_pango.found() and dep_pangocairo.found() and dep_fontconfig.found() and dep_glib.found()
|
|
deps_cairo_shared += [ dep_pango, dep_pangocairo, dep_fontconfig, dep_glib ]
|
|
config_h.set('HAVE_PANGO', '1')
|
|
endif
|
|
|
|
if get_option('image-jpeg')
|
|
dep_libjpeg = dependency('libjpeg', required: false)
|
|
if not dep_libjpeg.found()
|
|
dep_libjpeg = cc.find_library('jpeg', required: false)
|
|
endif
|
|
if not dep_libjpeg.found()
|
|
error('JPEG image loading requires libjpeg or jpeg, neither was found. Or, you can use \'-Dimage-jpeg=false\'.')
|
|
endif
|
|
deps_cairo_shared += dep_libjpeg
|
|
config_h.set('HAVE_JPEG', '1')
|
|
endif
|
|
|
|
if get_option('image-webp')
|
|
dep_webp = dependency('libwebp', required: false)
|
|
if not dep_webp.found()
|
|
error('WEBP image loading requires libwebp which was not found. Or, you can use \'-Dimage-webp=false\'.')
|
|
endif
|
|
deps_cairo_shared += dep_webp
|
|
config_h.set('HAVE_WEBP', '1')
|
|
endif
|
|
|
|
lib_cairo_shared = static_library(
|
|
'cairo-shared',
|
|
srcs_cairo_shared,
|
|
include_directories: common_inc,
|
|
dependencies: deps_cairo_shared,
|
|
install: false
|
|
)
|
|
dep_lib_cairo_shared = declare_dependency(
|
|
link_with: lib_cairo_shared,
|
|
dependencies: deps_cairo_shared
|
|
)
|
|
|
|
dep_matrix_c = declare_dependency(
|
|
sources: 'matrix.c',
|
|
include_directories: public_inc,
|
|
dependencies: dep_libm
|
|
)
|