mirror of
https://github.com/systemd/systemd
synced 2024-09-06 08:46:19 +00:00
20927c0eec
* fix error * remove options that are no longer supported * add missing options * stop completion if an option `--help` or `--version` is supplied [[[ zjs: a note for the reader: zshcompsys(1) in the section about optspecs in _arguments says: > Each of the forms above may be preceded by a list in parentheses of option names and argument num‐ > bers. If the given option is on the command line, the options and arguments indicated in parentheses > will not be offered. For example, ‘(-two -three 1)-one:...' completes the option ‘-one'; if this ap‐ > pears on the command line, the options -two and -three and the first ordinary argument will not be > completed after it. ‘(-foo):...' specifies an ordinary argument completion; -foo will not be com‐ > pleted if that argument is already present. > > Other items may appear in the list of excluded options to indicate various other items that should > not be applied when the current specification is matched: a single star (\*) for the rest arguments > (i.e. a specification of the form ‘\*:...'); a colon (:) for all normal (non-option-) arguments; and a > hyphen (-) for all options. For example, if ‘(\*)' appears before an option and the option appears on > the command line, the list of remaining arguments (those shown in the above table beginning with > ‘\*:') will not be completed. The intended effect of the change is to remove irrelevant completion matches from the completion. tl;dr: (- : ) prevents further completion ]]]
86 lines
3.8 KiB
Plaintext
86 lines
3.8 KiB
Plaintext
#compdef resolvectl systemd-resolve
|
|
# SPDX-License-Identifier: LGPL-2.1-or-later
|
|
#
|
|
# This file is part of systemd.
|
|
#
|
|
# systemd is free software; you can redistribute it and/or modify it
|
|
# under the terms of the GNU Lesser General Public License as published by
|
|
# the Free Software Foundation; either version 2.1 of the License, or
|
|
# (at your option) any later version.
|
|
#
|
|
# systemd is distributed in the hope that it will be useful, but
|
|
# WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
# General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU Lesser General Public License
|
|
# along with systemd; If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
(( $+functions[_resolvectl_protocols] )) ||
|
|
_resolvectl_protocols() {
|
|
local -a _protocol
|
|
_protocol=( $(_call_program protocol ${service} --legend=no --protocol help; echo help) )
|
|
_values 'protocol' "$_protocol[@]"
|
|
}
|
|
|
|
(( $+functions[_resolvectl_types] )) ||
|
|
_resolvectl_types() {
|
|
local -a _type
|
|
_type=( $(_call_program type ${service} --legend=no --type help; echo help) )
|
|
_values 'type' "$_type[@]"
|
|
}
|
|
|
|
(( $+functions[_resolvectl_classes] )) ||
|
|
_resolvectl_classes() {
|
|
local -a _class
|
|
_class=( $(_call_program class ${service} --legend=no --class help; echo help) )
|
|
_values 'class' "$_class[@]"
|
|
}
|
|
|
|
(( $+functions[_resolvectl_commands] )) ||
|
|
_resolvectl_commands() {
|
|
local -a _resolvectl_cmds
|
|
_resolvectl_cmds=(
|
|
default-route:"Configure per-interface default-route setting"
|
|
dns:"Configure per-interface DNS configuration"
|
|
dnsovertls:"Configure per-interface dnsovertls enabled status"
|
|
dnssec:"Configure per-interface dnssec enabled status"
|
|
domain:"Configure per-interface search and route-only domains"
|
|
flush-caches:"Flushes all DNS resource record caches the service maintains locally"
|
|
llmnr:"Configure per-interface llmnr enabled status"
|
|
mdns:"Configure per-interface mdns enabled status"
|
|
nta:"Configure per-interface nta domains"
|
|
openpgp:"Retrieve openpgp keys for an email"
|
|
query:"Resolve domain names, IPv4 and IPv6 addresses"
|
|
reset-server-features:"Flushes all feature level information the resolver has learned about specific servers"
|
|
reset-statistics:"Resets the statistics counter shown in statistics to zero"
|
|
revert:"Revert the per-interfce DNS configuration"
|
|
service:"Resolve DNS-SD and SRV services"
|
|
show-cache:"Show the current cache contents"
|
|
statistics:"Show resolver statistics"
|
|
status:"Show the global and per-link DNS settings currently in effect"
|
|
tlsa:"Query tlsa public keys stored as TLSA resource records"
|
|
)
|
|
|
|
if (( CURRENT == 1 )); then
|
|
_describe -t commands 'resolvectl commands' _resolvectl_cmds
|
|
fi
|
|
}
|
|
|
|
_arguments \
|
|
'(- *)'{-h,--help}'[Print a short help text and exit]' \
|
|
'(- *)--version[Print a short version string and exit]' \
|
|
'--legend=[Do not show headers and footers]:BOOL:(yes no)' \
|
|
'-4[Resolve IPv4 addresses]' \
|
|
'-6[Resolve IPv6 addresses]' \
|
|
'(-i --interface)'{-i+,--interface=}'[Look on interface]:interface:_net_interfaces' \
|
|
'(-p --protocol)'{-p+,--protocol=}'[Look via protocol]:protocol:_resolvectl_protocols' \
|
|
'(-t --type)'{-t+,--type=}'[Query RR with DNS type]:type:_resolvectl_types' \
|
|
'(-c --class)'{-c+,--class=}'[Query RR with DNS class]:class:_resolvectl_classes' \
|
|
'--service[Resolve services]' \
|
|
'--service-address=[Do not resolve address for services]:BOOL:(yes no)' \
|
|
'--service-txt=[Do not resolve TXT records for services]:BOOL:(yes no)' \
|
|
'--cname=[Do not follow CNAME redirects]:BOOL:(yes no)' \
|
|
'--search=[Do not use search domains]:BOOL:(yes no)' \
|
|
'*::default: _resolvectl_commands'
|