meson: move declarations of modules-load, nspawn, update-done, and update-utmp

meson.build

@@ -2412,6 +2412,7 @@ subdir('src/locale')
 subdir('src/login')
 subdir('src/machine')
 subdir('src/machine-id-setup')
+subdir('src/modules-load')
 subdir('src/mount')
 subdir('src/network')
 subdir('src/notify')
@@ -2451,6 +2452,8 @@ subdir('src/timedate')
 subdir('src/timesync')
 subdir('src/tmpfiles')
 subdir('src/tty-ask-password-agent')
+subdir('src/update-done')
+subdir('src/update-utmp')
 subdir('src/user-sessions')
 subdir('src/userdb')
 subdir('src/vconsole')
@@ -2680,59 +2683,6 @@ if want_tests != 'false'
              args : ['verify', '--resolve-names=never', all_rules])
 endif
 
-executable(
-        'systemd-update-done',
-        'src/update-done/update-done.c',
-        include_directories : includes,
-        link_with : [libshared],
-        dependencies : [userspace],
-        install_rpath : pkglibdir,
-        install : true,
-        install_dir : libexecdir)
-
-executable(
-        'systemd-update-utmp',
-        'src/update-utmp/update-utmp.c',
-        include_directories : includes,
-        link_with : [libshared],
-        dependencies : [libaudit,
-                        userspace],
-        install_rpath : pkglibdir,
-        install : (conf.get('ENABLE_UTMP') == 1),
-        install_dir : libexecdir)
-
-if conf.get('HAVE_KMOD') == 1
-        executable(
-                'systemd-modules-load',
-                'src/modules-load/modules-load.c',
-                include_directories : includes,
-                link_with : [libshared],
-                dependencies : [libkmod,
-                                userspace],
-                install_rpath : pkglibdir,
-                install : true,
-                install_dir : libexecdir)
-
-        meson.add_install_script('sh', '-c',
-                                 mkdir_p.format(modulesloaddir))
-        if install_sysconfdir
-                meson.add_install_script('sh', '-c',
-                                         mkdir_p.format(sysconfdir / 'modules-load.d'))
-        endif
-endif
-
-public_programs += executable(
-        'systemd-nspawn',
-        systemd_nspawn_sources,
-        include_directories : includes,
-        link_with : [libnspawn_core,
-                     libshared],
-        dependencies : [libblkid,
-                        libseccomp,
-                        userspace],
-        install_rpath : pkglibdir,
-        install : true)
-
 if conf.get('ENABLE_NETWORKD') == 1
         dbus_programs += executable(
                 'systemd-networkd',

src/modules-load/meson.build

@@ -0,0 +1,19 @@
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+executables += [
+        libexec_template + {
+                'name' : 'systemd-modules-load',
+                'conditions' : ['HAVE_KMOD'],
+                'sources' : files('modules-load.c'),
+                'dependencies' : libkmod,
+        },
+]
+
+if conf.get('HAVE_KMOD') == 1
+        meson.add_install_script('sh', '-c',
+                                 mkdir_p.format(modulesloaddir))
+        if install_sysconfdir
+                meson.add_install_script('sh', '-c',
+                                         mkdir_p.format(sysconfdir / 'modules-load.d'))
+        endif
+endif

src/nspawn/meson.build

@@ -35,7 +35,23 @@ libnspawn_core = static_library(
                         userspace],
         build_by_default : false)
 
-systemd_nspawn_sources = files('nspawn.c')
+nspawn_libs = [
+        libnspawn_core,
+        libshared,
+]
+
+executables += [
+        executable_template + {
+                'name' : 'systemd-nspawn',
+                'public' : true,
+                'sources' : files('nspawn.c'),
+                'link_with' : nspawn_libs,
+                'dependencies' : [
+                        libblkid,
+                        libseccomp,
+                ],
+        },
+]
 
 ############################################################
 

src/update-done/meson.build

@@ -0,0 +1,8 @@
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+executables += [
+        libexec_template + {
+                'name' : 'systemd-update-done',
+                'sources' : files('update-done.c'),
+        },
+]

src/update-utmp/meson.build

@@ -0,0 +1,10 @@
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+executables += [
+        libexec_template + {
+                'name' : 'systemd-update-utmp',
+                'conditions' : ['ENABLE_UTMP'],
+                'sources' : files('update-utmp.c'),
+                'dependencies' : libaudit,
+        },
+]