test: Add TEST-85-NETWORK to run systemd-networkd-tests.py

This adds a testsuite unit to run systemd-networkd-tests.py. This is
mkosi only for now as python is not available in the images set up
by the bash framework. We give the test a lower priority as it takes
a while to run so we want to start it as soon as possible.

test/TEST-85-NETWORK/Makefile

@@ -0,0 +1,6 @@
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+all setup run clean clean-again:
+	true
+
+.PHONY: all setup run clean clean-again

test/TEST-85-NETWORK/meson.build

@@ -0,0 +1,42 @@
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+name = fs.name(meson.current_source_dir())
+unit = configure_file(
+        input : files('../test.service.in'),
+        output : '@0@.service'.format(name),
+        configuration : integration_test_template['configuration'] + {
+                'command' : '@0@ --no-journal'.format(testdata_dir / 'test-network/systemd-networkd-tests.py')
+        },
+)
+
+foreach testcase : [
+        'NetworkctlTests',
+        'NetworkdMatchTests',
+        'WaitOnlineTests',
+        'NetworkdNetDevTests',
+        'NetworkdL2TPTests',
+        'NetworkdNetworkTests',
+        'NetworkdTCTests',
+        'NetworkdStateFileTests',
+        'NetworkdBondTests',
+        'NetworkdBridgeTests',
+        'NetworkdSRIOVTests',
+        'NetworkdLLDPTests',
+        'NetworkdRATests',
+        'NetworkdDHCPServerTests',
+        'NetworkdDHCPServerRelayAgentTests',
+        'NetworkdDHCPClientTests',
+        'NetworkdDHCPPDTests',
+        'NetworkdIPv6PrefixTests',
+        'NetworkdMTUTests',
+]
+        integration_tests += [
+                integration_test_template + {
+                        'name' : '@0@-@1@'.format(name, testcase),
+                        'unit' : unit,
+                        'cmdline' : integration_test_template['cmdline'] + [
+                                'systemd.setenv=TEST_MATCH_TESTCASE=@0@'.format(testcase)
+                        ],
+                },
+        ]
+endforeach

test/meson.build

@@ -370,6 +370,7 @@ foreach dirname : [
         'TEST-82-SOFTREBOOT',
         'TEST-83-BTRFS',
         'TEST-84-STORAGETM',
+        'TEST-85-NETWORK',
 ]
         subdir(dirname)
 endforeach