mirror of
https://gitlab.com/qemu-project/qemu
synced 2024-09-06 18:05:37 +00:00
![Ilya Leoshkevich](/assets/img/avatar_default.png)
tcg/ should not depend on accel/tcg/, but perf and debuginfo support provided by the latter are being used by tcg/tcg.c. Since that's the only user, move both to tcg/. Suggested-by: Philippe Mathieu-Daudé <philmd@linaro.org> Reviewed-by: Philippe Mathieu-Daudé <philmd@linaro.org> Signed-off-by: Ilya Leoshkevich <iii@linux.ibm.com> Reviewed-by: Richard Henderson <richard.henderson@linaro.org> Message-ID: <20231212003837.64090-5-iii@linux.ibm.com> Message-Id: <20240125054631.78867-5-philmd@linaro.org> Signed-off-by: Richard Henderson <richard.henderson@linaro.org>
51 lines
1.4 KiB
Meson
51 lines
1.4 KiB
Meson
if not get_option('tcg').allowed()
|
|
subdir_done()
|
|
endif
|
|
|
|
tcg_ss = ss.source_set()
|
|
|
|
tcg_ss.add(files(
|
|
'optimize.c',
|
|
'region.c',
|
|
'tcg.c',
|
|
'tcg-common.c',
|
|
'tcg-op.c',
|
|
'tcg-op-ldst.c',
|
|
'tcg-op-gvec.c',
|
|
'tcg-op-vec.c',
|
|
))
|
|
|
|
if get_option('tcg_interpreter')
|
|
libffi = dependency('libffi', version: '>=3.0', required: true,
|
|
method: 'pkg-config')
|
|
tcg_ss.add(libffi)
|
|
tcg_ss.add(files('tci.c'))
|
|
endif
|
|
|
|
tcg_ss.add(when: libdw, if_true: files('debuginfo.c'))
|
|
if host_os == 'linux'
|
|
tcg_ss.add(files('perf.c'))
|
|
endif
|
|
|
|
tcg_ss = tcg_ss.apply({})
|
|
|
|
libtcg_user = static_library('tcg_user',
|
|
tcg_ss.sources() + genh,
|
|
name_suffix: 'fa',
|
|
c_args: '-DCONFIG_USER_ONLY',
|
|
build_by_default: false)
|
|
|
|
tcg_user = declare_dependency(link_with: libtcg_user,
|
|
dependencies: tcg_ss.dependencies())
|
|
user_ss.add(tcg_user)
|
|
|
|
libtcg_system = static_library('tcg_system',
|
|
tcg_ss.sources() + genh,
|
|
name_suffix: 'fa',
|
|
c_args: '-DCONFIG_SOFTMMU',
|
|
build_by_default: false)
|
|
|
|
tcg_system = declare_dependency(link_with: libtcg_system,
|
|
dependencies: tcg_ss.dependencies())
|
|
system_ss.add(tcg_system)
|