mirror of
https://gitlab.com/qemu-project/qemu
synced 2024-07-08 20:17:27 +00:00
7cd50cbe4c
start.S currently cannot be compiled with Clang 16 and binutils 2.40:
ld: start.o(.text+0x8): misaligned symbol `__bss_start' (0xc1e5) for
relocation R_390_PC32DBL
According to the built-in linker script of ld, the symbol __bss_start
can actually point *before* the .bss section and does not need to have
any alignment, so in certain situations (like when using the internal
assembler of Clang), the __bss_start symbol can indeed be unaligned
and thus it is not suitable for being used with the "larl" instruction
that needs an address that is at least aligned to halfwords.
The problem went unnoticed so far since binutils <= 2.39 did not
check the alignment, but starting with binutils 2.40, such unaligned
addresses are now refused.
Fix it by loading the address indirectly instead.
Buglink: https://bugzilla.redhat.com/show_bug.cgi?id=2216662
Reported-by: Miroslav Rezanina <mrezanin@redhat.com>
Suggested-by: Andreas Krebbel <andreas.krebbel@de.ibm.com>
Message-Id: <20230629104821.194859-8-thuth@redhat.com>
Reviewed-by: Claudio Imbrenda <imbrenda@linux.ibm.com>
Signed-off-by: Thomas Huth <thuth@redhat.com>
132 lines
3.0 KiB
ArmAsm
132 lines
3.0 KiB
ArmAsm
/*
|
|
* First stage boot loader for virtio devices. The compiled output goes
|
|
* into the pc-bios directory of qemu.
|
|
*
|
|
* Copyright (c) 2013 Alexander Graf <agraf@suse.de>
|
|
* Copyright IBM Corp. 2013, 2017
|
|
*
|
|
* This work is licensed under the terms of the GNU GPL, version 2 or (at
|
|
* your option) any later version. See the COPYING file in the top-level
|
|
* directory.
|
|
*/
|
|
|
|
#define STACK_SIZE 0x8000
|
|
#define STACK_FRAME_SIZE 160
|
|
|
|
.globl _start
|
|
_start:
|
|
|
|
larl %r15,stack + STACK_SIZE - STACK_FRAME_SIZE /* Set up stack */
|
|
|
|
/* clear bss */
|
|
larl %r2,bss_start_literal /* __bss_start might be unaligned ... */
|
|
lg %r2,0(%r2) /* ... so load it indirectly */
|
|
larl %r3,_end
|
|
slgr %r3,%r2 /* get sizeof bss */
|
|
ltgr %r3,%r3 /* bss empty? */
|
|
jz done
|
|
aghi %r3,-1
|
|
srlg %r4,%r3,8 /* how many 256 byte chunks? */
|
|
ltgr %r4,%r4
|
|
lgr %r1,%r2
|
|
jz remainder
|
|
loop:
|
|
xc 0(256,%r1),0(%r1)
|
|
la %r1,256(%r1)
|
|
brctg %r4,loop
|
|
remainder:
|
|
larl %r2,memsetxc
|
|
ex %r3,0(%r2)
|
|
done:
|
|
/* set up a pgm exception disabled wait psw */
|
|
larl %r2,disabled_wait_psw
|
|
mvc 0x01d0(16),0(%r2)
|
|
j main /* And call C */
|
|
|
|
memsetxc:
|
|
xc 0(1,%r1),0(%r1)
|
|
|
|
/*
|
|
* void disabled_wait(void)
|
|
*
|
|
* stops the current guest cpu.
|
|
*/
|
|
.globl disabled_wait
|
|
disabled_wait:
|
|
larl %r1,disabled_wait_psw
|
|
lpswe 0(%r1)
|
|
1: j 1b
|
|
|
|
|
|
/*
|
|
* void consume_sclp_int(void)
|
|
*
|
|
* eats one sclp interrupt
|
|
*/
|
|
.globl consume_sclp_int
|
|
consume_sclp_int:
|
|
/* enable service interrupts in cr0 */
|
|
stctg %c0,%c0,0(%r15)
|
|
oi 6(%r15),0x2
|
|
lctlg %c0,%c0,0(%r15)
|
|
/* prepare external call handler */
|
|
larl %r1,external_new_code
|
|
stg %r1,0x1b8
|
|
larl %r1,external_new_mask
|
|
mvc 0x1b0(8),0(%r1)
|
|
/* load enabled wait PSW */
|
|
larl %r1,enabled_wait_psw
|
|
lpswe 0(%r1)
|
|
|
|
/*
|
|
* void consume_io_int(void)
|
|
*
|
|
* eats one I/O interrupt
|
|
*/
|
|
.globl consume_io_int
|
|
consume_io_int:
|
|
/* enable I/O interrupts in cr6 */
|
|
stctg %c6,%c6,0(%r15)
|
|
oi 4(%r15), 0xff
|
|
lctlg %c6,%c6,0(%r15)
|
|
/* prepare i/o call handler */
|
|
larl %r1,io_new_code
|
|
stg %r1,0x1f8
|
|
larl %r1,io_new_mask
|
|
mvc 0x1f0(8),0(%r1)
|
|
/* load enabled wait PSW */
|
|
larl %r1,enabled_wait_psw
|
|
lpswe 0(%r1)
|
|
|
|
external_new_code:
|
|
/* disable service interrupts in cr0 */
|
|
stctg %c0,%c0,0(%r15)
|
|
ni 6(%r15),0xfd
|
|
lctlg %c0,%c0,0(%r15)
|
|
br %r14
|
|
|
|
io_new_code:
|
|
/* disable I/O interrupts in cr6 */
|
|
stctg %c6,%c6,0(%r15)
|
|
ni 4(%r15),0x00
|
|
lctlg %c6,%c6,0(%r15)
|
|
br %r14
|
|
|
|
.align 8
|
|
bss_start_literal:
|
|
.quad __bss_start
|
|
disabled_wait_psw:
|
|
.quad 0x0002000180000000,0x0000000000000000
|
|
enabled_wait_psw:
|
|
.quad 0x0302000180000000,0x0000000000000000
|
|
external_new_mask:
|
|
.quad 0x0000000180000000
|
|
io_new_mask:
|
|
.quad 0x0000000180000000
|
|
|
|
.bss
|
|
.align 8
|
|
stack:
|
|
.space STACK_SIZE
|
|
.size stack,STACK_SIZE
|