mirror of
https://gitlab.com/qemu-project/qemu
synced 2024-09-16 01:03:31 +00:00
de6cd7599b
We use the user_ss[] array to hold the user emulation sources, and the softmmu_ss[] array to hold the system emulation ones. Hold the latter in the 'system_ss[]' array for parity with user emulation. Mechanical change doing: $ sed -i -e s/softmmu_ss/system_ss/g $(git grep -l softmmu_ss) Signed-off-by: Philippe Mathieu-Daudé <philmd@linaro.org> Reviewed-by: Richard Henderson <richard.henderson@linaro.org> Message-Id: <20230613133347.82210-10-philmd@linaro.org> Signed-off-by: Richard Henderson <richard.henderson@linaro.org>
46 lines
1.3 KiB
Meson
46 lines
1.3 KiB
Meson
if not get_option('tcg').allowed()
|
|
subdir_done()
|
|
endif
|
|
|
|
tcg_ss = ss.source_set()
|
|
|
|
tcg_ss.add(files(
|
|
'optimize.c',
|
|
'region.c',
|
|
'tcg.c',
|
|
'tcg-common.c',
|
|
'tcg-op.c',
|
|
'tcg-op-ldst.c',
|
|
'tcg-op-gvec.c',
|
|
'tcg-op-vec.c',
|
|
))
|
|
|
|
if get_option('tcg_interpreter')
|
|
libffi = dependency('libffi', version: '>=3.0', required: true,
|
|
method: 'pkg-config')
|
|
tcg_ss.add(libffi)
|
|
tcg_ss.add(files('tci.c'))
|
|
endif
|
|
|
|
tcg_ss = tcg_ss.apply(config_host, strict: false)
|
|
|
|
libtcg_user = static_library('tcg_user',
|
|
tcg_ss.sources() + genh,
|
|
name_suffix: 'fa',
|
|
c_args: '-DCONFIG_USER_ONLY',
|
|
build_by_default: have_user)
|
|
|
|
tcg_user = declare_dependency(link_with: libtcg_user,
|
|
dependencies: tcg_ss.dependencies())
|
|
user_ss.add(tcg_user)
|
|
|
|
libtcg_softmmu = static_library('tcg_softmmu',
|
|
tcg_ss.sources() + genh,
|
|
name_suffix: 'fa',
|
|
c_args: '-DCONFIG_SOFTMMU',
|
|
build_by_default: have_system)
|
|
|
|
tcg_softmmu = declare_dependency(link_with: libtcg_softmmu,
|
|
dependencies: tcg_ss.dependencies())
|
|
system_ss.add(tcg_softmmu)
|