mirror of
https://gitlab.com/qemu-project/qemu
synced 2024-11-05 20:35:44 +00:00
98b5362bdd
This moves these commands from MAINTAINERS sections "Human Monitor (HMP)" and "QMP" to "Overall Audio backends". Signed-off-by: Markus Armbruster <armbru@redhat.com> Message-Id: <20230124121946.1139465-3-armbru@redhat.com>
37 lines
969 B
Meson
37 lines
969 B
Meson
softmmu_ss.add([spice_headers, files('audio.c')])
|
|
softmmu_ss.add(files(
|
|
'audio-hmp-cmds.c',
|
|
'audio_legacy.c',
|
|
'mixeng.c',
|
|
'noaudio.c',
|
|
'wavaudio.c',
|
|
'wavcapture.c',
|
|
))
|
|
|
|
softmmu_ss.add(when: coreaudio, if_true: files('coreaudio.m'))
|
|
softmmu_ss.add(when: dsound, if_true: files('dsoundaudio.c', 'audio_win_int.c'))
|
|
|
|
audio_modules = {}
|
|
foreach m : [
|
|
['alsa', alsa, files('alsaaudio.c')],
|
|
['oss', oss, files('ossaudio.c')],
|
|
['pa', pulse, files('paaudio.c')],
|
|
['sdl', sdl, files('sdlaudio.c')],
|
|
['jack', jack, files('jackaudio.c')],
|
|
['sndio', sndio, files('sndioaudio.c')],
|
|
['spice', spice, files('spiceaudio.c')]
|
|
]
|
|
if m[1].found()
|
|
module_ss = ss.source_set()
|
|
module_ss.add(m[1], m[2])
|
|
audio_modules += {m[0] : module_ss}
|
|
endif
|
|
endforeach
|
|
|
|
if dbus_display
|
|
module_ss = ss.source_set()
|
|
module_ss.add(when: gio, if_true: files('dbusaudio.c'))
|
|
audio_modules += {'dbus': module_ss}
|
|
endif
|
|
|
|
modules += {'audio': audio_modules}
|