mirror of
https://gitlab.com/qemu-project/qemu
synced 2024-09-30 00:04:37 +00:00
20fdd01e51
Since commit0082475e26the plugin symbol list is unconditionally added to the linker flags, leading to a build failure: Undefined symbols for architecture arm64: "_qemu_plugin_entry_code", referenced from: <initial-undefines> ... ld: symbol(s) not found for architecture arm64 clang: error: linker command failed with exit code 1 (use -v to see invocation) ninja: build stopped: subcommand failed. Fix by restricting the whole meson file to the --enable-plugins configure argument. Fixes:0082475e26("meson: merge plugin_ldflags into emulator_link_args") Resolves: https://gitlab.com/qemu-project/qemu/-/issues/2476 Signed-off-by: Philippe Mathieu-Daudé <philmd@linaro.org> Acked-by: Richard Henderson <richard.henderson@linaro.org> Message-Id: <20240813112457.92560-1-philmd@linaro.org> Signed-off-by: Alex Bennée <alex.bennee@linaro.org> Message-Id: <20240813202329.1237572-9-alex.bennee@linaro.org>
43 lines
1.4 KiB
Meson
43 lines
1.4 KiB
Meson
if not get_option('plugins')
|
|
subdir_done()
|
|
endif
|
|
|
|
# Modules need more symbols than just those in plugins/qemu-plugins.symbols
|
|
if not enable_modules
|
|
if host_os == 'darwin'
|
|
configure_file(
|
|
input: files('qemu-plugins.symbols'),
|
|
output: 'qemu-plugins-ld64.symbols',
|
|
capture: true,
|
|
command: ['sed', '-ne', 's/^[[:space:]]*\\(qemu_.*\\);/_\\1/p', '@INPUT@'])
|
|
emulator_link_args += ['-Wl,-exported_symbols_list,plugins/qemu-plugins-ld64.symbols']
|
|
else
|
|
emulator_link_args += ['-Xlinker', '--dynamic-list=' + (meson.project_source_root() / 'plugins/qemu-plugins.symbols')]
|
|
endif
|
|
endif
|
|
|
|
if host_os == 'windows'
|
|
dlltool = find_program('dlltool', required: true)
|
|
|
|
# Generate a .lib file for plugins to link against.
|
|
# First, create a .def file listing all the symbols a plugin should expect to have
|
|
# available in qemu
|
|
win32_plugin_def = configure_file(
|
|
input: files('qemu-plugins.symbols'),
|
|
output: 'qemu_plugin_api.def',
|
|
capture: true,
|
|
command: ['sed', '-e', '0,/^/s//EXPORTS/; s/[{};]//g', '@INPUT@'])
|
|
# then use dlltool to assemble a delaylib.
|
|
win32_qemu_plugin_api_lib = configure_file(
|
|
input: win32_plugin_def,
|
|
output: 'libqemu_plugin_api.a',
|
|
command: [dlltool, '--input-def', '@INPUT@',
|
|
'--output-delaylib', '@OUTPUT@', '--dllname', 'qemu.exe']
|
|
)
|
|
endif
|
|
specific_ss.add(files(
|
|
'loader.c',
|
|
'core.c',
|
|
'api.c',
|
|
))
|