mirror of
https://github.com/torvalds/linux
synced 2024-10-16 08:19:01 +00:00
6dcc5627f6
These are all functions which are invoked from elsewhere, so annotate them as global using the new SYM_FUNC_START and their ENDPROC's by SYM_FUNC_END. Make sure ENTRY/ENDPROC is not defined on X86_64, given these were the last users. Signed-off-by: Jiri Slaby <jslaby@suse.cz> Signed-off-by: Borislav Petkov <bp@suse.de> Reviewed-by: Rafael J. Wysocki <rafael.j.wysocki@intel.com> [hibernate] Reviewed-by: Boris Ostrovsky <boris.ostrovsky@oracle.com> [xen bits] Acked-by: Herbert Xu <herbert@gondor.apana.org.au> [crypto] Cc: Allison Randal <allison@lohutok.net> Cc: Andrey Ryabinin <aryabinin@virtuozzo.com> Cc: Andy Lutomirski <luto@kernel.org> Cc: Andy Shevchenko <andy@infradead.org> Cc: Ard Biesheuvel <ard.biesheuvel@linaro.org> Cc: Armijn Hemel <armijn@tjaldur.nl> Cc: Cao jin <caoj.fnst@cn.fujitsu.com> Cc: Darren Hart <dvhart@infradead.org> Cc: Dave Hansen <dave.hansen@linux.intel.com> Cc: "David S. Miller" <davem@davemloft.net> Cc: Enrico Weigelt <info@metux.net> Cc: Greg Kroah-Hartman <gregkh@linuxfoundation.org> Cc: Herbert Xu <herbert@gondor.apana.org.au> Cc: "H. Peter Anvin" <hpa@zytor.com> Cc: Ingo Molnar <mingo@redhat.com> Cc: Jim Mattson <jmattson@google.com> Cc: Joerg Roedel <joro@8bytes.org> Cc: Josh Poimboeuf <jpoimboe@redhat.com> Cc: Juergen Gross <jgross@suse.com> Cc: Kate Stewart <kstewart@linuxfoundation.org> Cc: "Kirill A. Shutemov" <kirill.shutemov@linux.intel.com> Cc: kvm ML <kvm@vger.kernel.org> Cc: Len Brown <len.brown@intel.com> Cc: linux-arch@vger.kernel.org Cc: linux-crypto@vger.kernel.org Cc: linux-efi <linux-efi@vger.kernel.org> Cc: linux-efi@vger.kernel.org Cc: linux-pm@vger.kernel.org Cc: Mark Rutland <mark.rutland@arm.com> Cc: Matt Fleming <matt@codeblueprint.co.uk> Cc: Paolo Bonzini <pbonzini@redhat.com> Cc: Pavel Machek <pavel@ucw.cz> Cc: Peter Zijlstra <peterz@infradead.org> Cc: platform-driver-x86@vger.kernel.org Cc: "Radim Krčmář" <rkrcmar@redhat.com> Cc: Sean Christopherson <sean.j.christopherson@intel.com> Cc: Stefano Stabellini <sstabellini@kernel.org> Cc: "Steven Rostedt (VMware)" <rostedt@goodmis.org> Cc: Thomas Gleixner <tglx@linutronix.de> Cc: Vitaly Kuznetsov <vkuznets@redhat.com> Cc: Wanpeng Li <wanpengli@tencent.com> Cc: Wei Huang <wei@redhat.com> Cc: x86-ml <x86@kernel.org> Cc: xen-devel@lists.xenproject.org Cc: Xiaoyao Li <xiaoyao.li@linux.intel.com> Link: https://lkml.kernel.org/r/20191011115108.12392-25-jslaby@suse.cz
317 lines
7.7 KiB
ArmAsm
317 lines
7.7 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* Copyright (C) 2014 Steven Rostedt, Red Hat Inc
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/ptrace.h>
|
|
#include <asm/ftrace.h>
|
|
#include <asm/export.h>
|
|
#include <asm/nospec-branch.h>
|
|
#include <asm/unwind_hints.h>
|
|
#include <asm/frame.h>
|
|
|
|
.code64
|
|
.section .entry.text, "ax"
|
|
|
|
# define function_hook __fentry__
|
|
EXPORT_SYMBOL(__fentry__)
|
|
|
|
#ifdef CONFIG_FRAME_POINTER
|
|
/* Save parent and function stack frames (rip and rbp) */
|
|
# define MCOUNT_FRAME_SIZE (8+16*2)
|
|
#else
|
|
/* No need to save a stack frame */
|
|
# define MCOUNT_FRAME_SIZE 0
|
|
#endif /* CONFIG_FRAME_POINTER */
|
|
|
|
/* Size of stack used to save mcount regs in save_mcount_regs */
|
|
#define MCOUNT_REG_SIZE (SS+8 + MCOUNT_FRAME_SIZE)
|
|
|
|
/*
|
|
* gcc -pg option adds a call to 'mcount' in most functions.
|
|
* When -mfentry is used, the call is to 'fentry' and not 'mcount'
|
|
* and is done before the function's stack frame is set up.
|
|
* They both require a set of regs to be saved before calling
|
|
* any C code and restored before returning back to the function.
|
|
*
|
|
* On boot up, all these calls are converted into nops. When tracing
|
|
* is enabled, the call can jump to either ftrace_caller or
|
|
* ftrace_regs_caller. Callbacks (tracing functions) that require
|
|
* ftrace_regs_caller (like kprobes) need to have pt_regs passed to
|
|
* it. For this reason, the size of the pt_regs structure will be
|
|
* allocated on the stack and the required mcount registers will
|
|
* be saved in the locations that pt_regs has them in.
|
|
*/
|
|
|
|
/*
|
|
* @added: the amount of stack added before calling this
|
|
*
|
|
* After this is called, the following registers contain:
|
|
*
|
|
* %rdi - holds the address that called the trampoline
|
|
* %rsi - holds the parent function (traced function's return address)
|
|
* %rdx - holds the original %rbp
|
|
*/
|
|
.macro save_mcount_regs added=0
|
|
|
|
#ifdef CONFIG_FRAME_POINTER
|
|
/* Save the original rbp */
|
|
pushq %rbp
|
|
|
|
/*
|
|
* Stack traces will stop at the ftrace trampoline if the frame pointer
|
|
* is not set up properly. If fentry is used, we need to save a frame
|
|
* pointer for the parent as well as the function traced, because the
|
|
* fentry is called before the stack frame is set up, where as mcount
|
|
* is called afterward.
|
|
*/
|
|
|
|
/* Save the parent pointer (skip orig rbp and our return address) */
|
|
pushq \added+8*2(%rsp)
|
|
pushq %rbp
|
|
movq %rsp, %rbp
|
|
/* Save the return address (now skip orig rbp, rbp and parent) */
|
|
pushq \added+8*3(%rsp)
|
|
pushq %rbp
|
|
movq %rsp, %rbp
|
|
#endif /* CONFIG_FRAME_POINTER */
|
|
|
|
/*
|
|
* We add enough stack to save all regs.
|
|
*/
|
|
subq $(MCOUNT_REG_SIZE - MCOUNT_FRAME_SIZE), %rsp
|
|
movq %rax, RAX(%rsp)
|
|
movq %rcx, RCX(%rsp)
|
|
movq %rdx, RDX(%rsp)
|
|
movq %rsi, RSI(%rsp)
|
|
movq %rdi, RDI(%rsp)
|
|
movq %r8, R8(%rsp)
|
|
movq %r9, R9(%rsp)
|
|
/*
|
|
* Save the original RBP. Even though the mcount ABI does not
|
|
* require this, it helps out callers.
|
|
*/
|
|
#ifdef CONFIG_FRAME_POINTER
|
|
movq MCOUNT_REG_SIZE-8(%rsp), %rdx
|
|
#else
|
|
movq %rbp, %rdx
|
|
#endif
|
|
movq %rdx, RBP(%rsp)
|
|
|
|
/* Copy the parent address into %rsi (second parameter) */
|
|
movq MCOUNT_REG_SIZE+8+\added(%rsp), %rsi
|
|
|
|
/* Move RIP to its proper location */
|
|
movq MCOUNT_REG_SIZE+\added(%rsp), %rdi
|
|
movq %rdi, RIP(%rsp)
|
|
|
|
/*
|
|
* Now %rdi (the first parameter) has the return address of
|
|
* where ftrace_call returns. But the callbacks expect the
|
|
* address of the call itself.
|
|
*/
|
|
subq $MCOUNT_INSN_SIZE, %rdi
|
|
.endm
|
|
|
|
.macro restore_mcount_regs
|
|
movq R9(%rsp), %r9
|
|
movq R8(%rsp), %r8
|
|
movq RDI(%rsp), %rdi
|
|
movq RSI(%rsp), %rsi
|
|
movq RDX(%rsp), %rdx
|
|
movq RCX(%rsp), %rcx
|
|
movq RAX(%rsp), %rax
|
|
|
|
/* ftrace_regs_caller can modify %rbp */
|
|
movq RBP(%rsp), %rbp
|
|
|
|
addq $MCOUNT_REG_SIZE, %rsp
|
|
|
|
.endm
|
|
|
|
#ifdef CONFIG_DYNAMIC_FTRACE
|
|
|
|
SYM_FUNC_START(function_hook)
|
|
retq
|
|
SYM_FUNC_END(function_hook)
|
|
|
|
SYM_FUNC_START(ftrace_caller)
|
|
/* save_mcount_regs fills in first two parameters */
|
|
save_mcount_regs
|
|
|
|
SYM_INNER_LABEL(ftrace_caller_op_ptr, SYM_L_GLOBAL)
|
|
/* Load the ftrace_ops into the 3rd parameter */
|
|
movq function_trace_op(%rip), %rdx
|
|
|
|
/* regs go into 4th parameter (but make it NULL) */
|
|
movq $0, %rcx
|
|
|
|
SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)
|
|
call ftrace_stub
|
|
|
|
restore_mcount_regs
|
|
|
|
/*
|
|
* The code up to this label is copied into trampolines so
|
|
* think twice before adding any new code or changing the
|
|
* layout here.
|
|
*/
|
|
SYM_INNER_LABEL(ftrace_epilogue, SYM_L_GLOBAL)
|
|
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
SYM_INNER_LABEL(ftrace_graph_call, SYM_L_GLOBAL)
|
|
jmp ftrace_stub
|
|
#endif
|
|
|
|
/*
|
|
* This is weak to keep gas from relaxing the jumps.
|
|
* It is also used to copy the retq for trampolines.
|
|
*/
|
|
WEAK(ftrace_stub)
|
|
retq
|
|
SYM_FUNC_END(ftrace_caller)
|
|
|
|
SYM_FUNC_START(ftrace_regs_caller)
|
|
/* Save the current flags before any operations that can change them */
|
|
pushfq
|
|
|
|
/* added 8 bytes to save flags */
|
|
save_mcount_regs 8
|
|
/* save_mcount_regs fills in first two parameters */
|
|
|
|
SYM_INNER_LABEL(ftrace_regs_caller_op_ptr, SYM_L_GLOBAL)
|
|
/* Load the ftrace_ops into the 3rd parameter */
|
|
movq function_trace_op(%rip), %rdx
|
|
|
|
/* Save the rest of pt_regs */
|
|
movq %r15, R15(%rsp)
|
|
movq %r14, R14(%rsp)
|
|
movq %r13, R13(%rsp)
|
|
movq %r12, R12(%rsp)
|
|
movq %r11, R11(%rsp)
|
|
movq %r10, R10(%rsp)
|
|
movq %rbx, RBX(%rsp)
|
|
/* Copy saved flags */
|
|
movq MCOUNT_REG_SIZE(%rsp), %rcx
|
|
movq %rcx, EFLAGS(%rsp)
|
|
/* Kernel segments */
|
|
movq $__KERNEL_DS, %rcx
|
|
movq %rcx, SS(%rsp)
|
|
movq $__KERNEL_CS, %rcx
|
|
movq %rcx, CS(%rsp)
|
|
/* Stack - skipping return address and flags */
|
|
leaq MCOUNT_REG_SIZE+8*2(%rsp), %rcx
|
|
movq %rcx, RSP(%rsp)
|
|
|
|
ENCODE_FRAME_POINTER
|
|
|
|
/* regs go into 4th parameter */
|
|
leaq (%rsp), %rcx
|
|
|
|
SYM_INNER_LABEL(ftrace_regs_call, SYM_L_GLOBAL)
|
|
call ftrace_stub
|
|
|
|
/* Copy flags back to SS, to restore them */
|
|
movq EFLAGS(%rsp), %rax
|
|
movq %rax, MCOUNT_REG_SIZE(%rsp)
|
|
|
|
/* Handlers can change the RIP */
|
|
movq RIP(%rsp), %rax
|
|
movq %rax, MCOUNT_REG_SIZE+8(%rsp)
|
|
|
|
/* restore the rest of pt_regs */
|
|
movq R15(%rsp), %r15
|
|
movq R14(%rsp), %r14
|
|
movq R13(%rsp), %r13
|
|
movq R12(%rsp), %r12
|
|
movq R10(%rsp), %r10
|
|
movq RBX(%rsp), %rbx
|
|
|
|
restore_mcount_regs
|
|
|
|
/* Restore flags */
|
|
popfq
|
|
|
|
/*
|
|
* As this jmp to ftrace_epilogue can be a short jump
|
|
* it must not be copied into the trampoline.
|
|
* The trampoline will add the code to jump
|
|
* to the return.
|
|
*/
|
|
SYM_INNER_LABEL(ftrace_regs_caller_end, SYM_L_GLOBAL)
|
|
|
|
jmp ftrace_epilogue
|
|
|
|
SYM_FUNC_END(ftrace_regs_caller)
|
|
|
|
|
|
#else /* ! CONFIG_DYNAMIC_FTRACE */
|
|
|
|
SYM_FUNC_START(function_hook)
|
|
cmpq $ftrace_stub, ftrace_trace_function
|
|
jnz trace
|
|
|
|
fgraph_trace:
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
cmpq $ftrace_stub, ftrace_graph_return
|
|
jnz ftrace_graph_caller
|
|
|
|
cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
|
|
jnz ftrace_graph_caller
|
|
#endif
|
|
|
|
SYM_INNER_LABEL(ftrace_stub, SYM_L_GLOBAL)
|
|
retq
|
|
|
|
trace:
|
|
/* save_mcount_regs fills in first two parameters */
|
|
save_mcount_regs
|
|
|
|
/*
|
|
* When DYNAMIC_FTRACE is not defined, ARCH_SUPPORTS_FTRACE_OPS is not
|
|
* set (see include/asm/ftrace.h and include/linux/ftrace.h). Only the
|
|
* ip and parent ip are used and the list function is called when
|
|
* function tracing is enabled.
|
|
*/
|
|
movq ftrace_trace_function, %r8
|
|
CALL_NOSPEC %r8
|
|
restore_mcount_regs
|
|
|
|
jmp fgraph_trace
|
|
SYM_FUNC_END(function_hook)
|
|
#endif /* CONFIG_DYNAMIC_FTRACE */
|
|
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
SYM_FUNC_START(ftrace_graph_caller)
|
|
/* Saves rbp into %rdx and fills first parameter */
|
|
save_mcount_regs
|
|
|
|
leaq MCOUNT_REG_SIZE+8(%rsp), %rsi
|
|
movq $0, %rdx /* No framepointers needed */
|
|
call prepare_ftrace_return
|
|
|
|
restore_mcount_regs
|
|
|
|
retq
|
|
SYM_FUNC_END(ftrace_graph_caller)
|
|
|
|
SYM_CODE_START(return_to_handler)
|
|
UNWIND_HINT_EMPTY
|
|
subq $24, %rsp
|
|
|
|
/* Save the return values */
|
|
movq %rax, (%rsp)
|
|
movq %rdx, 8(%rsp)
|
|
movq %rbp, %rdi
|
|
|
|
call ftrace_return_to_handler
|
|
|
|
movq %rax, %rdi
|
|
movq 8(%rsp), %rdx
|
|
movq (%rsp), %rax
|
|
addq $24, %rsp
|
|
JMP_NOSPEC %rdi
|
|
SYM_CODE_END(return_to_handler)
|
|
#endif
|