mirror of
https://github.com/torvalds/linux
synced 2024-09-28 15:31:19 +00:00
66d857b08b
There is a lot of common code that could be shared between the m68k and m68knommu arch branches. It makes sense to merge the two branches into a single directory structure so that we can more easily share that common code. This is a brute force merge, based on a script from Stephen King <sfking@fdwdc.com>, which was originally written by Arnd Bergmann <arnd@arndb.de>. > The script was inspired by the script Sam Ravnborg used to merge the > includes from m68knommu. For those files common to both arches but > differing in content, the m68k version of the file is renamed to > <file>_mm.<ext> and the m68knommu version of the file is moved into the > corresponding m68k directory and renamed <file>_no.<ext> and a small > wrapper file <file>.<ext> is used to select between the two version. Files > that are common to both but don't differ are removed from the m68knommu > tree and files and directories that are unique to the m68knommu tree are > moved to the m68k tree. Finally, the arch/m68knommu tree is removed. > > To select between the the versions of the files, the wrapper uses > > #ifdef CONFIG_MMU > #include <file>_mm.<ext> > #else > #include <file>_no.<ext> > #endif On top of this file merge I have done a simplistic merge of m68k and m68knommu Kconfig, which primarily attempts to keep existing options and menus in place. Other than a handful of options being moved it produces identical .config outputs on m68k and m68knommu targets I tested it on. With this in place there is now quite a bit of scope for merge cleanups in future patches. Signed-off-by: Greg Ungerer <gerg@uclinux.org>
129 lines
1.6 KiB
ArmAsm
129 lines
1.6 KiB
ArmAsm
|
|
#define MEM_END 0x00800000 /* Memory size 8Mb */
|
|
|
|
#undef CRT_DEBUG
|
|
|
|
.macro PUTC CHAR
|
|
#ifdef CRT_DEBUG
|
|
moveq #\CHAR, %d7
|
|
jsr putc
|
|
#endif
|
|
.endm
|
|
|
|
.global _start
|
|
.global _rambase
|
|
.global _ramvec
|
|
.global _ramstart
|
|
.global _ramend
|
|
|
|
.data
|
|
|
|
/*
|
|
* Set up the usable of RAM stuff
|
|
*/
|
|
_rambase:
|
|
.long 0
|
|
_ramvec:
|
|
.long 0
|
|
_ramstart:
|
|
.long 0
|
|
_ramend:
|
|
.long 0
|
|
|
|
.text
|
|
|
|
_start:
|
|
|
|
/*
|
|
* Setup initial stack
|
|
*/
|
|
/* disable all interrupts */
|
|
movew #0x2700, %sr
|
|
movel #-1, 0xfffff304
|
|
movel #MEM_END-4, %sp
|
|
|
|
PUTC '\r'
|
|
PUTC '\n'
|
|
PUTC 'A'
|
|
PUTC 'B'
|
|
|
|
/*
|
|
* Determine end of RAM
|
|
*/
|
|
|
|
movel #MEM_END, %a0
|
|
movel %a0, _ramend
|
|
|
|
PUTC 'C'
|
|
|
|
/*
|
|
* Move ROM filesystem above bss :-)
|
|
*/
|
|
|
|
moveal #_sbss, %a0 /* romfs at the start of bss */
|
|
moveal #_ebss, %a1 /* Set up destination */
|
|
movel %a0, %a2 /* Copy of bss start */
|
|
|
|
movel 8(%a0), %d1 /* Get size of ROMFS */
|
|
addql #8, %d1 /* Allow for rounding */
|
|
andl #0xfffffffc, %d1 /* Whole words */
|
|
|
|
addl %d1, %a0 /* Copy from end */
|
|
addl %d1, %a1 /* Copy from end */
|
|
movel %a1, _ramstart /* Set start of ram */
|
|
|
|
1:
|
|
movel -(%a0), %d0 /* Copy dword */
|
|
movel %d0, -(%a1)
|
|
cmpl %a0, %a2 /* Check if at end */
|
|
bne 1b
|
|
|
|
PUTC 'D'
|
|
|
|
/*
|
|
* Initialize BSS segment to 0
|
|
*/
|
|
|
|
lea _sbss, %a0
|
|
lea _ebss, %a1
|
|
|
|
/* Copy 0 to %a0 until %a0 == %a1 */
|
|
2: cmpal %a0, %a1
|
|
beq 1f
|
|
clrl (%a0)+
|
|
bra 2b
|
|
1:
|
|
|
|
PUTC 'E'
|
|
|
|
/*
|
|
* Load the current task pointer and stack
|
|
*/
|
|
|
|
lea init_thread_union, %a0
|
|
lea 0x2000(%a0), %sp
|
|
|
|
PUTC 'F'
|
|
PUTC '\r'
|
|
PUTC '\n'
|
|
|
|
/*
|
|
* Go
|
|
*/
|
|
|
|
jmp start_kernel
|
|
|
|
/*
|
|
* Local functions
|
|
*/
|
|
|
|
#ifdef CRT_DEBUG
|
|
putc:
|
|
moveb %d7, 0xfffff907
|
|
1:
|
|
movew 0xfffff906, %d7
|
|
andw #0x2000, %d7
|
|
beq 1b
|
|
rts
|
|
#endif
|