mirror of
https://github.com/torvalds/linux
synced 2024-09-20 02:57:25 +00:00
c75a33c84b
The NL_SET_ERR_MSG_MOD macro is used to report a string describing an error message to userspace via the netlink extended ACK structure. It should not have a trailing newline. Add a cocci script which catches cases where the newline marker is present. Using this script, fix the handful of cases which accidentally included a trailing new line. I couldn't figure out a way to get a patch mode working, so this script only implements context, report, and org. Signed-off-by: Jacob Keller <jacob.e.keller@intel.com> Cc: Jakub Kicinski <kuba@kernel.org> Cc: Andy Whitcroft <apw@canonical.com> Cc: Joe Perches <joe@perches.com> Signed-off-by: David S. Miller <davem@davemloft.net>
76 lines
1.6 KiB
Plaintext
76 lines
1.6 KiB
Plaintext
// SPDX-License-Identifier: GPL-2.0-only
|
|
///
|
|
/// Catch strings ending in newline with GENL_SET_ERR_MSG, NL_SET_ERR_MSG,
|
|
/// NL_SET_ERR_MSG_MOD.
|
|
///
|
|
// Confidence: Very High
|
|
// Copyright: (C) 2020 Intel Corporation
|
|
// URL: http://coccinelle.lip6.fr/
|
|
// Options: --no-includes --include-headers
|
|
|
|
virtual context
|
|
virtual org
|
|
virtual report
|
|
|
|
@r depends on context || org || report@
|
|
expression e;
|
|
constant m;
|
|
position p;
|
|
@@
|
|
\(GENL_SET_ERR_MSG\|NL_SET_ERR_MSG\|NL_SET_ERR_MSG_MOD\)(e,m@p)
|
|
|
|
@script:python@
|
|
m << r.m;
|
|
@@
|
|
|
|
if not m.endswith("\\n\""):
|
|
cocci.include_match(False)
|
|
|
|
@r1 depends on r@
|
|
identifier fname;
|
|
expression r.e;
|
|
constant r.m;
|
|
position r.p;
|
|
@@
|
|
fname(e,m@p)
|
|
|
|
//----------------------------------------------------------
|
|
// For context mode
|
|
//----------------------------------------------------------
|
|
|
|
@depends on context && r@
|
|
identifier r1.fname;
|
|
expression r.e;
|
|
constant r.m;
|
|
@@
|
|
* fname(e,m)
|
|
|
|
//----------------------------------------------------------
|
|
// For org mode
|
|
//----------------------------------------------------------
|
|
|
|
@script:python depends on org@
|
|
fname << r1.fname;
|
|
m << r.m;
|
|
p << r.p;
|
|
@@
|
|
|
|
if m.endswith("\\n\""):
|
|
msg="WARNING avoid newline at end of message in %s" % (fname)
|
|
msg_safe=msg.replace("[","@(").replace("]",")")
|
|
coccilib.org.print_todo(p[0], msg_safe)
|
|
|
|
//----------------------------------------------------------
|
|
// For report mode
|
|
//----------------------------------------------------------
|
|
|
|
@script:python depends on report@
|
|
fname << r1.fname;
|
|
m << r.m;
|
|
p << r.p;
|
|
@@
|
|
|
|
if m.endswith("\\n\""):
|
|
msg="WARNING avoid newline at end of message in %s" % (fname)
|
|
coccilib.report.print_report(p[0], msg)
|