mirror of
https://github.com/freebsd/freebsd-src
synced 2024-10-15 04:43:53 +00:00
fd45b686f9
Notable upstream pull request merges: #15793401c3563dlibzfs: use zfs_strerror() in place of strerror() #15793692f0dabalibzfs: make userquota_propname_decode threadsafe #157980cbf13529libnvpair.c: replace strstr() with strchr() for a single character #1581278e8c1f84Remove list_size struct member from list implementation #15816aeb33776fUpdate vdev devid and physpath if changed between imports #158188161b7327Don't assert mg_initialized due to device addition race #15823c3fd7a521Update man pages to time(1) from time(2) #15825884a48d99zpool wait: print timestamp before the header Obtained from: OpenZFS OpenZFS commit:2e6b3c4d94
54 lines
1.2 KiB
Plaintext
54 lines
1.2 KiB
Plaintext
dnl #
|
|
dnl # Check file_operations->fsync interface.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_FSYNC], [
|
|
ZFS_LINUX_TEST_SRC([fsync_without_dentry], [
|
|
#include <linux/fs.h>
|
|
|
|
static int test_fsync(struct file *f, int x) { return 0; }
|
|
|
|
static const struct file_operations
|
|
fops __attribute__ ((unused)) = {
|
|
.fsync = test_fsync,
|
|
};
|
|
],[])
|
|
|
|
ZFS_LINUX_TEST_SRC([fsync_range], [
|
|
#include <linux/fs.h>
|
|
|
|
static int test_fsync(struct file *f, loff_t a, loff_t b, int c)
|
|
{ return 0; }
|
|
|
|
static const struct file_operations
|
|
fops __attribute__ ((unused)) = {
|
|
.fsync = test_fsync,
|
|
};
|
|
],[])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC], [
|
|
dnl #
|
|
dnl # Linux 2.6.35 - Linux 3.0 API
|
|
dnl #
|
|
AC_MSG_CHECKING([whether fops->fsync() wants no dentry])
|
|
ZFS_LINUX_TEST_RESULT([fsync_without_dentry], [
|
|
AC_MSG_RESULT([yes])
|
|
AC_DEFINE(HAVE_FSYNC_WITHOUT_DENTRY, 1,
|
|
[fops->fsync() without dentry])
|
|
],[
|
|
AC_MSG_RESULT([no])
|
|
|
|
dnl #
|
|
dnl # Linux 3.1 - 3.x API
|
|
dnl #
|
|
AC_MSG_CHECKING([whether fops->fsync() wants range])
|
|
ZFS_LINUX_TEST_RESULT([fsync_range], [
|
|
AC_MSG_RESULT([range])
|
|
AC_DEFINE(HAVE_FSYNC_RANGE, 1,
|
|
[fops->fsync() with range])
|
|
],[
|
|
ZFS_LINUX_TEST_ERROR([fops->fsync])
|
|
])
|
|
])
|
|
])
|