mirror of
https://github.com/freebsd/freebsd-src
synced 2024-10-07 00:50:50 +00:00
b985c9cafd
Notable upstream pull request merges: #15839c3f2f1aa2vdev probe to slow disk can stall mmp write checker #158885044c4e3fFast Dedup: ZAP Shrinking #15996db499e68fOverflowing refreservation is bad #1611867d13998bMake more taskq parameters writable #1612821bc066ecFix updating the zvol_htable when renaming a zvol #16130645b83307Improve write issue taskqs utilization #161318fd3a5d02Slightly improve dnode hash #16134a6edc0adbzio: try to execute TYPE_NULL ZIOs on the current task #16141b28461b7cFix arcstats for FreeBSD after zfetch support Obtained from: OpenZFS OpenZFS commit:8f1b7a6fa6
45 lines
1.4 KiB
Plaintext
45 lines
1.4 KiB
Plaintext
dnl
|
|
dnl Checks for libunwind, which usually does a better job than backtrace() when
|
|
dnl resolving symbols in the stack backtrace. Newer versions have support for
|
|
dnl getting info about the object file the function came from, so we look for
|
|
dnl that too and use it if found.
|
|
dnl
|
|
AC_DEFUN([ZFS_AC_CONFIG_USER_LIBUNWIND], [
|
|
AC_ARG_WITH([libunwind],
|
|
AS_HELP_STRING([--with-libunwind],
|
|
[use libunwind for backtraces in userspace assertions]),
|
|
[],
|
|
[with_libunwind=auto])
|
|
|
|
AS_IF([test "x$with_libunwind" != "xno"], [
|
|
ZFS_AC_FIND_SYSTEM_LIBRARY(LIBUNWIND, [libunwind], [libunwind.h], [], [unwind], [], [
|
|
dnl unw_get_elf_filename() is sometimes a macro, other
|
|
dnl times a proper symbol, so we can't just do a link
|
|
dnl check; we need to include the header properly.
|
|
AX_SAVE_FLAGS
|
|
CFLAGS="$CFLAGS $LIBUNWIND_CFLAGS"
|
|
LIBS="$LIBS $LIBUNWIND_LIBS"
|
|
AC_MSG_CHECKING([for unw_get_elf_filename in libunwind])
|
|
AC_LINK_IFELSE([
|
|
AC_LANG_PROGRAM([
|
|
#define UNW_LOCAL_ONLY
|
|
#include <libunwind.h>
|
|
], [
|
|
unw_get_elf_filename(0, 0, 0, 0);
|
|
])
|
|
], [
|
|
AC_MSG_RESULT([yes])
|
|
AC_DEFINE(HAVE_LIBUNWIND_ELF, 1,
|
|
[libunwind has unw_get_elf_filename])
|
|
], [
|
|
AC_MSG_RESULT([no])
|
|
])
|
|
AX_RESTORE_FLAGS
|
|
], [
|
|
AS_IF([test "x$with_libunwind" = "xyes"], [
|
|
AC_MSG_FAILURE([--with-libunwind was given, but libunwind is not available, try installing libunwind-devel])
|
|
])
|
|
])
|
|
])
|
|
])
|