dnl ##### Check for FreeType 2.0.5+.
dnl ##### (Note: FT_Get_Name_Index was added in FT 2.0.5, and is
dnl ##### the reason that Xpdf requires 2.0.5+.)

KDE_FIND_PATH(freetype-config, FREETYPE_CONFIG, [${prefix}/bin ${exec_prefix}/bin /usr/local/bin /opt/local/bin], [
  AC_MSG_WARN([Could not find libfreetype anywhere, check http://www.freetype.org/])
])

if test -n "$FREETYPE_CONFIG"; then
  vers=`$FREETYPE_CONFIG --version 2>/dev/null | sed -e 's/libfreetype //' | awk 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
  if test -n "$vers" && test "$vers" -ge 9000000; then
    LIBFREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
    LIBFREETYPE_RPATH=
    for args in $LIBFREETYPE_LIBS; do
      case $args in
        -L*) LIBFREETYPE_RPATH="$LIBFREETYPE_RPATH $args" ;;
      esac
    done
    LIBFREETYPE_RPATH=`echo $LIBFREETYPE_RPATH | sed -e "s/-L/-R/g"`
    LIBFREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
  else
    AC_MSG_WARN([You need at least libfreetype 2.0.5])
  fi
fi

AC_SUBST(LIBFREETYPE_LIBS)
AC_SUBST(LIBFREETYPE_CFLAGS)
AC_SUBST(LIBFREETYPE_RPATH)


dnl ##### Check for libpaper (Debian).
LIBPAPER_LIBS=
KDE_CHECK_HEADER(paper.h, [
  LIBPAPER_LIBS='-lpaper'
  AC_DEFINE_UNQUOTED(HAVE_PAPER_H, 1, [Define to 1 if you have the <paper.h>  header file.])
])
AC_SUBST(LIBPAPER_LIBS)

AC_CHECK_FUNCS(fseek64 mkstemp mkstemps popen)

AC_FIND_FILE(xpdfrc, [/etc /usr/local/etc], xpdfrc)
if test "$xpdfrc" != NO; then
  AC_DEFINE_UNQUOTED(SYSTEM_XPDFRC, "$xpdfrc/xpdfrc", [Define the location your xpdfrc])
fi