mirror of
https://github.com/dart-lang/sdk
synced 2024-10-14 15:47:08 +00:00
8cbc4f3982
This change adds the required support to benchmark DDC just like dart2js. The ddb tool gains the following options: --compile-vm-options=VM-OPTIONS The value of the DART_VM_OPTIONS environment variable set when running dartdevc. This option is required to measure the memory use of dartdevc while compiling. --packages=PACKAGES-FILE The .packages file to use when compiling. This option is required for special benchmarks with a .packages in a subdirectory and is generally useful. --out=OUTPUT-FILE Write the compiled javascript to this path and the other generated files along it. This option makes the benchmark configuration easier and is generally useful. The dartdevc and dartdevc.bat scripts in the released Dart SDK now gains support for the DART_VM_OPTIONS environment variable, just like the dart2js scripts. This feature is needed to measure the memory usage of the Dart VM executing dartdevc. tools/bots/try_benchmarks.sh now tests that ddb can compile and run benchmarks using the needed features. Change-Id: Ib1ef07b0888a8c0cf900fe2fbb5697aab733db08 Reviewed-on: https://dart-review.googlesource.com/c/sdk/+/118440 Reviewed-by: Nate Bosch <nbosch@google.com> Commit-Queue: Jonas Termansen <sortie@google.com>
60 lines
1.9 KiB
Batchfile
60 lines
1.9 KiB
Batchfile
@echo off
|
|
REM Copyright (c) 2013, the Dart project authors. Please see the AUTHORS file
|
|
REM for details. All rights reserved. Use of this source code is governed by a
|
|
REM BSD-style license that can be found in the LICENSE file.
|
|
|
|
setlocal
|
|
rem Handle the case where dart-sdk/bin has been symlinked to.
|
|
set DIR_NAME_WITH_SLASH=%~dp0
|
|
set DIR_NAME=%DIR_NAME_WITH_SLASH:~0,-1%%
|
|
call :follow_links "%DIR_NAME%", RETURNED_BIN_DIR
|
|
rem Get rid of surrounding quotes.
|
|
for %%i in ("%RETURNED_BIN_DIR%") do set BIN_DIR=%%~fi
|
|
|
|
set DART=%BIN_DIR%\dart
|
|
set SNAPSHOT=%BIN_DIR%\snapshots\dartdevc.dart.snapshot
|
|
|
|
rem Get absolute full name for SDK_DIR.
|
|
for %%i in ("%BIN_DIR%\..\") do set SDK_DIR=%%~fi
|
|
|
|
rem Remove trailing backslash if there is one
|
|
if %SDK_DIR:~-1%==\ set SDK_DIR=%SDK_DIR:~0,-1%
|
|
|
|
set SDK_ARG=--dart-sdk=%SDK_DIR%
|
|
|
|
set EXTRA_VM_OPTIONS=
|
|
|
|
rem We allow extra vm options to be passed in through an environment variable.
|
|
if not "_%DART_VM_OPTIONS%_" == "__" (
|
|
set EXTRA_VM_OPTIONS=%EXTRA_VM_OPTIONS% %DART_VM_OPTIONS%
|
|
)
|
|
|
|
"%DART%" %EXTRA_VM_OPTIONS% "%SNAPSHOT%" "%SDK_ARG%" %*
|
|
|
|
endlocal
|
|
|
|
exit /b %errorlevel%
|
|
|
|
rem Follow the symbolic links (junctions points) using `dir to determine the
|
|
rem canonical path. Output with a link looks something like this
|
|
rem
|
|
rem 01/03/2013 10:11 PM <JUNCTION> abc def
|
|
rem [c:\dart_bleeding\dart-repo.9\dart\out\ReleaseIA32\dart-sdk]
|
|
rem
|
|
rem So in the output of 'dir /a:l "targetdir"' we are looking for a filename
|
|
rem surrounded by right angle bracket and left square bracket. Once we get
|
|
rem the filename, which is name of the link, we recursively follow that.
|
|
:follow_links
|
|
setlocal
|
|
for %%i in (%1) do set result=%%~fi
|
|
set current=
|
|
for /f "usebackq tokens=2 delims=[]" %%i in (`dir /a:l "%~dp1" 2^>nul ^
|
|
^| find "> %~n1 ["`) do (
|
|
set current=%%i
|
|
)
|
|
if not "%current%"=="" call :follow_links "%current%", result
|
|
endlocal & set %~2=%result%
|
|
goto :eof
|
|
|
|
:end
|