mirror of
https://github.com/dart-lang/sdk
synced 2024-11-02 08:20:31 +00:00
77 lines
2.4 KiB
Batchfile
77 lines
2.4 KiB
Batchfile
@echo off
|
|
REM Copyright (c) 2013, the Dart project authors. Please see the AUTHORS file
|
|
REM for details. All rights reserved. Use of this source code is governed by a
|
|
REM BSD-style license that can be found in the LICENSE file.
|
|
|
|
setlocal
|
|
rem Handle the case where dart-sdk/bin has been symlinked to.
|
|
set DIR_NAME_WITH_SLASH=%~dp0
|
|
set DIR_NAME=%DIR_NAME_WITH_SLASH:~0,-1%%
|
|
call :follow_links "%DIR_NAME%", RETURNED_BIN_DIR
|
|
rem Get rid of surrounding quotes.
|
|
for %%i in ("%RETURNED_BIN_DIR%") do set BIN_DIR=%%~fi
|
|
|
|
set DART=%BIN_DIR%\dart
|
|
|
|
rem Get absolute full name for SDK_DIR.
|
|
for %%i in ("%BIN_DIR%\..\") do set SDK_DIR=%%~fi
|
|
|
|
rem Remove trailing backslash if there is one
|
|
if %SDK_DIR:~-1%==\ set SDK_DIR=%SDK_DIR:~0,-1%
|
|
|
|
set SDK_ARG=--dart-sdk=%SDK_DIR%
|
|
|
|
set EXTRA_VM_OPTIONS=
|
|
|
|
if _%DARTANALYZER_DEVELOPER_MODE%_ == _1_ (
|
|
set EXTRA_VM_OPTIONS=%EXTRA_VM_OPTIONS% --checked
|
|
)
|
|
|
|
rem We allow extra vm options to be passed in through an environment variable.
|
|
if not "_%DART_VM_OPTIONS%_" == "__" (
|
|
set EXTRA_VM_OPTIONS=%EXTRA_VM_OPTIONS% %DART_VM_OPTIONS%
|
|
)
|
|
|
|
rem Get absolute full name for DART_ROOT.
|
|
for %%i in ("%SDK_DIR%\..\") do set DART_ROOT=%%~fi
|
|
|
|
rem Remove trailing backslash if there is one
|
|
if %DART_ROOT:~-1%==\ set DART_ROOT=%DART_ROOT:~0,-1%
|
|
|
|
set ANALYZER=%DART_ROOT%\pkg\analyzer_cli\bin\analyzer.dart
|
|
|
|
rem DART_CONFIGURATION defaults to ReleaseX64
|
|
if "%DART_CONFIGURATION%"=="" set DART_CONFIGURATION=ReleaseX64
|
|
|
|
set BUILD_DIR=%DART_ROOT%\build\%DART_CONFIGURATION%
|
|
|
|
set PACKAGE_ROOT=%BUILD_DIR%\packages
|
|
|
|
"%DART%" %EXTRA_VM_OPTIONS% "--package-root=%PACKAGE_ROOT%" "%ANALYZER%" "%SDK_ARG%" %*
|
|
|
|
endlocal
|
|
|
|
exit /b %errorlevel%
|
|
|
|
rem Follow the symbolic links (junctions points) using `dir to determine the
|
|
rem canonical path. Output with a link looks something like this
|
|
rem
|
|
rem 01/03/2013 10:11 PM <JUNCTION> abc def
|
|
rem [c:\dart_bleeding\dart-repo.9\dart\build\ReleaseIA32\dart-sdk]
|
|
rem
|
|
rem So in the output of 'dir /a:l "targetdir"' we are looking for a filename
|
|
rem surrounded by right angle bracket and left square bracket. Once we get
|
|
rem the filename, which is name of the link, we recursively follow that.
|
|
:follow_links
|
|
setlocal
|
|
for %%i in (%1) do set result=%%~fi
|
|
set current=
|
|
for /f "usebackq tokens=2 delims=[]" %%i in (`dir /a:l "%~dp1" 2^>nul ^
|
|
^| find "> %~n1 ["`) do (
|
|
set current=%%i
|
|
)
|
|
if not "%current%"=="" call :follow_links "%current%", result
|
|
endlocal & set %~2=%result%
|
|
goto :eof
|
|
|
|
:end
|