mirror of
https://github.com/dart-lang/sdk
synced 2024-09-06 00:59:09 +00:00
cd6c7ed56c
Fixes https://github.com/dart-lang/sdk/issues/21770. Change-Id: If54923d6f636901c3c3170a014138d85cb6560e9 Reviewed-on: https://dart-review.googlesource.com/c/sdk/+/158484 Reviewed-by: Jaime Wren <jwren@google.com> Commit-Queue: Alexander Aprelev <aam@google.com>
54 lines
1.5 KiB
Batchfile
54 lines
1.5 KiB
Batchfile
@echo off
|
|
REM Copyright (c) 2012, the Dart project authors. Please see the AUTHORS file
|
|
REM for details. All rights reserved. Use of this source code is governed by a
|
|
REM BSD-style license that can be found in the LICENSE file.
|
|
|
|
setlocal
|
|
rem Handle the case where dart-sdk/bin has been symlinked to.
|
|
set DIR_NAME_WITH_SLASH=%~dp0
|
|
set DIR_NAME=%DIR_NAME_WITH_SLASH:~0,-1%%
|
|
call :follow_links "%DIR_NAME%", RETURNED_BIN_DIR
|
|
rem Get rid of surrounding quotes.
|
|
for %%i in ("%RETURNED_BIN_DIR%") do set BIN_DIR=%%~fi
|
|
|
|
rem Get absolute full name for SDK_DIR.
|
|
for %%i in ("%BIN_DIR%\..\") do set SDK_DIR=%%~fi
|
|
|
|
rem Remove trailing backslash if there is one
|
|
IF %SDK_DIR:~-1%==\ set SDK_DIR=%SDK_DIR:~0,-1%
|
|
|
|
set VM_OPTIONS=
|
|
set USING_DART_1=
|
|
|
|
rem We allow extra vm options to be passed in through an environment variable.
|
|
if not "_%DART_VM_OPTIONS%_" == "__" (
|
|
set VM_OPTIONS=%VM_OPTIONS% %DART_VM_OPTIONS%
|
|
for %%o in (%DART_VM_OPTIONS%) do (
|
|
if "%%o" equ "--no-preview-dart-2" set USING_DART_1=y
|
|
)
|
|
)
|
|
|
|
if defined USING_DART_1 (
|
|
echo "Pub no longer supports Dart 1"
|
|
) else (
|
|
"%BIN_DIR%\dart" %VM_OPTIONS% "%BIN_DIR%\snapshots\pub.dart.snapshot" %*
|
|
)
|
|
|
|
endlocal
|
|
|
|
exit /b %errorlevel%
|
|
|
|
:follow_links
|
|
setlocal
|
|
for %%i in (%1) do set result=%%~fi
|
|
set current=
|
|
for /f "usebackq tokens=2 delims=[]" %%i in (`dir /a:l "%~dp1" 2^>nul ^
|
|
^| %SystemRoot%\System32\find.exe "> %~n1 [" 2^>nul`) do (
|
|
set current=%%i
|
|
)
|
|
if not "%current%"=="" call :follow_links "%current%", result
|
|
endlocal & set %~2=%result%
|
|
goto :eof
|
|
|
|
:end
|