mirror of
https://github.com/dart-lang/sdk
synced 2024-09-16 02:57:35 +00:00
81e428fd39
This has a few advantages: - We can track dependencies more precisely - ninja can assemble things in parallel as they're ready rather than sequentially all at once. - It is easier to customize SDKs depending on target platform, e.g. Fuchsia. This CL also has a number of cleanups: - Defining is_fuchsia and is_fuchsia host so we don't always have to check - Piping through toolchain overrides in more places - Fixing bugs in copy_tree.py, not using list_files.py, which is broken on Windows related #29558 R=whesse@google.com Review-Url: https://codereview.chromium.org/2848943003 .
251 lines
8.8 KiB
Plaintext
251 lines
8.8 KiB
Plaintext
# Copyright (c) 2013 The Chromium Authors. All rights reserved.
|
|
# Use of this source code is governed by a BSD-style license that can be
|
|
# found in the LICENSE file.
|
|
|
|
# TODO(brettw) Use "gcc_toolchain.gni" like the Linux toolchains. This requires
|
|
# some enhancements since the commands on Mac are slightly different than on
|
|
# Linux.
|
|
|
|
import("../goma.gni")
|
|
import("//build/config/mac/mac_sdk.gni")
|
|
|
|
assert(host_os == "mac")
|
|
|
|
import("//build/toolchain/clang.gni")
|
|
import("//build/toolchain/goma.gni")
|
|
import("//build/config/sysroot.gni")
|
|
|
|
if (use_goma) {
|
|
goma_prefix = "$goma_dir/gomacc "
|
|
} else {
|
|
goma_prefix = ""
|
|
}
|
|
|
|
# This will copy the gyp-mac-tool to the build directory. We pass in the source
|
|
# file of the win tool.
|
|
gyp_mac_tool_source =
|
|
rebase_path("//third_party/gyp/pylib/gyp/mac_tool.py", root_build_dir)
|
|
exec_script("setup_toolchain.py", [ gyp_mac_tool_source ])
|
|
|
|
# Shared toolchain definition. Invocations should set toolchain_os to set the
|
|
# build args in this definition.
|
|
template("mac_toolchain") {
|
|
toolchain(target_name) {
|
|
assert(defined(invoker.cc), "mac_toolchain() must specify a \"cc\" value")
|
|
assert(defined(invoker.cxx), "mac_toolchain() must specify a \"cxx\" value")
|
|
assert(defined(invoker.ld), "mac_toolchain() must specify a \"ld\" value")
|
|
assert(defined(invoker.toolchain_cpu),
|
|
"mac_toolchain() must specify a \"toolchain_cpu\"")
|
|
assert(defined(invoker.toolchain_os),
|
|
"mac_toolchain() must specify a \"toolchain_os\"")
|
|
|
|
# We can't do string interpolation ($ in strings) on things with dots in
|
|
# them. To allow us to use $cc below, for example, we create copies of
|
|
# these values in our scope.
|
|
cc = invoker.cc
|
|
cxx = invoker.cxx
|
|
ld = invoker.ld
|
|
|
|
# Make these apply to all tools below.
|
|
lib_switch = "-l"
|
|
lib_dir_switch = "-L"
|
|
|
|
sysroot_flags = ""
|
|
|
|
if (defined(invoker.sysroot_flags)) {
|
|
sysroot_flags = invoker.sysroot_flags
|
|
}
|
|
|
|
toolchain_flags = ""
|
|
if (invoker.toolchain_cpu == "i386") {
|
|
toolchain_flags = "-m32"
|
|
}
|
|
|
|
tool("cc") {
|
|
depfile = "{{output}}.d"
|
|
command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags $toolchain_flags {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
|
|
depsformat = "gcc"
|
|
description = "CC {{output}}"
|
|
outputs = [
|
|
"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
|
|
]
|
|
}
|
|
|
|
tool("cxx") {
|
|
depfile = "{{output}}.d"
|
|
command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags $toolchain_flags {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
|
|
depsformat = "gcc"
|
|
description = "CXX {{output}}"
|
|
outputs = [
|
|
"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
|
|
]
|
|
}
|
|
|
|
tool("asm") {
|
|
# For GCC we can just use the C compiler to compile assembly.
|
|
depfile = "{{output}}.d"
|
|
command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags $toolchain_flags {{asmflags}} -c {{source}} -o {{output}}"
|
|
depsformat = "gcc"
|
|
description = "ASM {{output}}"
|
|
outputs = [
|
|
"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
|
|
]
|
|
}
|
|
|
|
tool("objc") {
|
|
depfile = "{{output}}.d"
|
|
command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags $toolchain_flags {{cflags}} {{cflags_c}} {{cflags_objc}} -c {{source}} -o {{output}}"
|
|
depsformat = "gcc"
|
|
description = "OBJC {{output}}"
|
|
outputs = [
|
|
"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
|
|
]
|
|
}
|
|
|
|
tool("objcxx") {
|
|
depfile = "{{output}}.d"
|
|
command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags $toolchain_flags {{cflags}} {{cflags_cc}} {{cflags_objcc}} -c {{source}} -o {{output}}"
|
|
depsformat = "gcc"
|
|
description = "OBJCXX {{output}}"
|
|
outputs = [
|
|
"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
|
|
]
|
|
}
|
|
|
|
tool("alink") {
|
|
command = "rm -f {{output}} && ./gyp-mac-tool filter-libtool libtool -static -o {{output}} {{inputs}}"
|
|
description = "LIBTOOL-STATIC {{output}}"
|
|
outputs = [
|
|
"{{target_out_dir}}/{{target_output_name}}{{output_extension}}",
|
|
]
|
|
default_output_extension = ".a"
|
|
output_prefix = "lib"
|
|
}
|
|
|
|
tool("solink") {
|
|
dylib = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}" # eg "./libfoo.dylib"
|
|
rspfile = dylib + ".rsp"
|
|
|
|
# These variables are not build into GN but are helpers that implement
|
|
# (1) linking to produce a .so, (2) extracting the symbols from that file
|
|
# to a temporary file, (3) if the temporary file has differences from the
|
|
# existing .TOC file, overwrite it, oterwise, don't change it.
|
|
#
|
|
# As a special case, if the library reexports symbols from other dynamic
|
|
# libraries, we always update the .TOC and skip the temporary file and
|
|
# diffing steps, since that library always needs to be re-linked.
|
|
tocname = dylib + ".TOC"
|
|
temporary_tocname = dylib + ".tmp"
|
|
|
|
does_reexport_command = "[ ! -e $dylib -o ! -e $tocname ] || otool -l $dylib | grep -q LC_REEXPORT_DYLIB"
|
|
link_command = "$ld -shared $sysroot_flags $toolchain_flags {{ldflags}} -o $dylib -Wl,-filelist,$rspfile {{solibs}} {{libs}}"
|
|
replace_command = "if ! cmp -s $temporary_tocname $tocname; then mv $temporary_tocname $tocname"
|
|
extract_toc_command = "{ otool -l $dylib | grep LC_ID_DYLIB -A 5; nm -gP $dylib | cut -f1-2 -d' ' | grep -v U\$\$; true; }"
|
|
|
|
command = "if $does_reexport_command ; then $link_command && $extract_toc_command > $tocname; else $link_command && $extract_toc_command > $temporary_tocname && $replace_command ; fi; fi"
|
|
|
|
rspfile_content = "{{inputs_newline}}"
|
|
|
|
description = "SOLINK {{output}}"
|
|
|
|
# Use this for {{output_extension}} expansions unless a target manually
|
|
# overrides it (in which case {{output_extension}} will be what the target
|
|
# specifies).
|
|
default_output_extension = ".dylib"
|
|
|
|
output_prefix = "lib"
|
|
|
|
# Since the above commands only updates the .TOC file when it changes, ask
|
|
# Ninja to check if the timestamp actually changed to know if downstream
|
|
# dependencies should be recompiled.
|
|
restat = true
|
|
|
|
# Tell GN about the output files. It will link to the dylib but use the
|
|
# tocname for dependency management.
|
|
outputs = [
|
|
dylib,
|
|
tocname,
|
|
]
|
|
link_output = dylib
|
|
depend_output = tocname
|
|
}
|
|
|
|
tool("link") {
|
|
exename = "{{target_output_name}}{{output_extension}}"
|
|
outfile = "{{root_out_dir}}/$exename"
|
|
rspfile = "$outfile.rsp"
|
|
|
|
if (defined(invoker.strip)) {
|
|
stripped_outfile = "{{root_out_dir}}/exe.stripped/$exename"
|
|
}
|
|
|
|
command = "$ld $sysroot_flags $toolchain_flags {{ldflags}} -Xlinker -rpath -Xlinker @executable_path/Frameworks -o $outfile -Wl,-filelist,$rspfile {{solibs}} {{libs}}"
|
|
if (defined(invoker.strip)) {
|
|
strip = invoker.strip
|
|
strip_command = "${strip} -x -o $stripped_outfile $outfile"
|
|
command += " && " + strip_command
|
|
}
|
|
|
|
description = "LINK $outfile"
|
|
rspfile_content = "{{inputs_newline}}"
|
|
outputs = [
|
|
outfile,
|
|
]
|
|
if (defined(invoker.strip)) {
|
|
outputs += [ stripped_outfile ]
|
|
}
|
|
}
|
|
|
|
tool("stamp") {
|
|
command = "touch {{output}}"
|
|
description = "STAMP {{output}}"
|
|
}
|
|
|
|
tool("copy") {
|
|
command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
|
|
description = "COPY {{source}} {{output}}"
|
|
}
|
|
|
|
toolchain_args = {
|
|
current_cpu = invoker.toolchain_cpu
|
|
current_os = invoker.toolchain_os
|
|
|
|
# These values need to be passed through unchanged.
|
|
target_os = target_os
|
|
target_cpu = target_cpu
|
|
|
|
if (defined(invoker.is_clang)) {
|
|
is_clang = invoker.is_clang
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
# Toolchain used for Mac host targets.
|
|
mac_toolchain("clang_x64") {
|
|
toolchain_cpu = "x64"
|
|
toolchain_os = "mac"
|
|
prefix = rebase_path("//buildtools/toolchain/clang+llvm-x86_64-darwin/bin",
|
|
root_build_dir)
|
|
cc = "${goma_prefix}$prefix/clang"
|
|
cxx = "${goma_prefix}$prefix/clang++"
|
|
ld = cxx
|
|
strip = "${prefix}/strip"
|
|
is_clang = true
|
|
sysroot_flags = "-isysroot $mac_sdk_path -mmacosx-version-min=$mac_sdk_min"
|
|
}
|
|
|
|
# Toolchain used for Mac host (i386) targets.
|
|
mac_toolchain("clang_x86") {
|
|
toolchain_cpu = "i386"
|
|
toolchain_os = "mac"
|
|
prefix = rebase_path("//buildtools/toolchain/clang+llvm-x86_64-darwin/bin",
|
|
root_build_dir)
|
|
cc = "${goma_prefix}$prefix/clang"
|
|
cxx = "${goma_prefix}$prefix/clang++"
|
|
ld = cxx
|
|
strip = "${prefix}/strip"
|
|
is_clang = true
|
|
sysroot_flags = "-isysroot $mac_sdk_path -mmacosx-version-min=$mac_sdk_min"
|
|
}
|