mirror of
https://gitlab.gnome.org/GNOME/nautilus
synced 2024-10-01 13:34:16 +00:00
0e6e3946eb
Tracker SPARQL is now TinySPARQL. Tracker Miners is now LocalSearch. The old DBus and library APIs still work so there is no rush there. But the executables and git repositories need to be updated now. https://discourse.gnome.org/t/renaming-tracker-git-and-tracker-sparql-git-and-changing-default-branch/21461
33 lines
1.3 KiB
Meson
33 lines
1.3 KiB
Meson
# Files needed for running LocalSearch (historically known as Tracker) inside
|
|
# the Flatpak sandbox, for systems which don't have a suitable version of
|
|
# LocalSearch in the host OS.
|
|
#
|
|
# We must export the .service files from the sandbox so they work on the
|
|
# session bus. This means the LocalSearch domain name must correspond with the
|
|
# application ID.
|
|
|
|
domain_ontologies_dir = get_option('datadir') / 'localsearch3' / 'domain-ontologies'
|
|
dbus_services_dir = get_option('datadir') / 'dbus-1' / 'services'
|
|
|
|
tracker_domain_config = configuration_data()
|
|
tracker_domain_config.set('application_id', application_id)
|
|
tracker_domain_config.set('domain_rule', get_option('prefix') / domain_ontologies_dir / application_id + '.domain.rule')
|
|
|
|
configure_file(
|
|
input: 'org.gnome.Nautilus.domain.rule.in',
|
|
output: application_id + '.domain.rule',
|
|
configuration: tracker_domain_config,
|
|
install_dir: domain_ontologies_dir)
|
|
|
|
configure_file(
|
|
input: 'org.gnome.Nautilus.Tracker3.Miner.Extract.service.in',
|
|
output: application_id + '.Tracker3.Miner.Extract.service',
|
|
configuration: tracker_domain_config,
|
|
install_dir: dbus_services_dir)
|
|
|
|
configure_file(
|
|
input: 'org.gnome.Nautilus.Tracker3.Miner.Files.service.in',
|
|
output: application_id + '.Tracker3.Miner.Files.service',
|
|
configuration: tracker_domain_config,
|
|
install_dir: dbus_services_dir)
|