mirror of
https://github.com/godotengine/godot
synced 2024-09-16 04:16:49 +00:00
9b61c855ef
This includes all three light types and IBL, but does not include shadows or any form of GI
128 lines
4.6 KiB
GLSL
128 lines
4.6 KiB
GLSL
#ifdef USE_BCS
|
|
uniform vec3 bcs;
|
|
#endif
|
|
|
|
#ifdef USE_COLOR_CORRECTION
|
|
#ifdef USE_1D_LUT
|
|
uniform sampler2D source_color_correction; //texunit:-1
|
|
#else
|
|
uniform sampler3D source_color_correction; //texunit:-1
|
|
#endif
|
|
#endif
|
|
|
|
layout(std140) uniform TonemapData { //ubo:0
|
|
float exposure;
|
|
float white;
|
|
int tonemapper;
|
|
int pad;
|
|
};
|
|
|
|
vec3 apply_bcs(vec3 color, vec3 bcs) {
|
|
color = mix(vec3(0.0), color, bcs.x);
|
|
color = mix(vec3(0.5), color, bcs.y);
|
|
color = mix(vec3(dot(vec3(1.0), color) * 0.33333), color, bcs.z);
|
|
|
|
return color;
|
|
}
|
|
#ifdef USE_COLOR_CORRECTION
|
|
#ifdef USE_1D_LUT
|
|
vec3 apply_color_correction(vec3 color) {
|
|
color.r = texture(source_color_correction, vec2(color.r, 0.0f)).r;
|
|
color.g = texture(source_color_correction, vec2(color.g, 0.0f)).g;
|
|
color.b = texture(source_color_correction, vec2(color.b, 0.0f)).b;
|
|
return color;
|
|
}
|
|
#else
|
|
vec3 apply_color_correction(vec3 color) {
|
|
return textureLod(source_color_correction, color, 0.0).rgb;
|
|
}
|
|
#endif
|
|
#endif
|
|
|
|
vec3 tonemap_filmic(vec3 color, float p_white) {
|
|
// exposure bias: input scale (color *= bias, white *= bias) to make the brightness consistent with other tonemappers
|
|
// also useful to scale the input to the range that the tonemapper is designed for (some require very high input values)
|
|
// has no effect on the curve's general shape or visual properties
|
|
const float exposure_bias = 2.0f;
|
|
const float A = 0.22f * exposure_bias * exposure_bias; // bias baked into constants for performance
|
|
const float B = 0.30f * exposure_bias;
|
|
const float C = 0.10f;
|
|
const float D = 0.20f;
|
|
const float E = 0.01f;
|
|
const float F = 0.30f;
|
|
|
|
vec3 color_tonemapped = ((color * (A * color + C * B) + D * E) / (color * (A * color + B) + D * F)) - E / F;
|
|
float p_white_tonemapped = ((p_white * (A * p_white + C * B) + D * E) / (p_white * (A * p_white + B) + D * F)) - E / F;
|
|
|
|
return color_tonemapped / p_white_tonemapped;
|
|
}
|
|
|
|
// Adapted from https://github.com/TheRealMJP/BakingLab/blob/master/BakingLab/ACES.hlsl
|
|
// (MIT License).
|
|
vec3 tonemap_aces(vec3 color, float p_white) {
|
|
const float exposure_bias = 1.8f;
|
|
const float A = 0.0245786f;
|
|
const float B = 0.000090537f;
|
|
const float C = 0.983729f;
|
|
const float D = 0.432951f;
|
|
const float E = 0.238081f;
|
|
|
|
// Exposure bias baked into transform to save shader instructions. Equivalent to `color *= exposure_bias`
|
|
const mat3 rgb_to_rrt = mat3(
|
|
vec3(0.59719f * exposure_bias, 0.35458f * exposure_bias, 0.04823f * exposure_bias),
|
|
vec3(0.07600f * exposure_bias, 0.90834f * exposure_bias, 0.01566f * exposure_bias),
|
|
vec3(0.02840f * exposure_bias, 0.13383f * exposure_bias, 0.83777f * exposure_bias));
|
|
|
|
const mat3 odt_to_rgb = mat3(
|
|
vec3(1.60475f, -0.53108f, -0.07367f),
|
|
vec3(-0.10208f, 1.10813f, -0.00605f),
|
|
vec3(-0.00327f, -0.07276f, 1.07602f));
|
|
|
|
color *= rgb_to_rrt;
|
|
vec3 color_tonemapped = (color * (color + A) - B) / (color * (C * color + D) + E);
|
|
color_tonemapped *= odt_to_rgb;
|
|
|
|
p_white *= exposure_bias;
|
|
float p_white_tonemapped = (p_white * (p_white + A) - B) / (p_white * (C * p_white + D) + E);
|
|
|
|
return color_tonemapped / p_white_tonemapped;
|
|
}
|
|
|
|
vec3 tonemap_reinhard(vec3 color, float p_white) {
|
|
return (p_white * color + color) / (color * p_white + p_white);
|
|
}
|
|
|
|
// This expects 0-1 range input.
|
|
vec3 linear_to_srgb(vec3 color) {
|
|
//color = clamp(color, vec3(0.0), vec3(1.0));
|
|
//const vec3 a = vec3(0.055f);
|
|
//return mix((vec3(1.0f) + a) * pow(color.rgb, vec3(1.0f / 2.4f)) - a, 12.92f * color.rgb, lessThan(color.rgb, vec3(0.0031308f)));
|
|
// Approximation from http://chilliant.blogspot.com/2012/08/srgb-approximations-for-hlsl.html
|
|
return max(vec3(1.055) * pow(color, vec3(0.416666667)) - vec3(0.055), vec3(0.0));
|
|
}
|
|
|
|
// This expects 0-1 range input, outside that range it behaves poorly.
|
|
vec3 srgb_to_linear(vec3 color) {
|
|
// Approximation from http://chilliant.blogspot.com/2012/08/srgb-approximations-for-hlsl.html
|
|
return color * (color * (color * 0.305306011 + 0.682171111) + 0.012522878);
|
|
}
|
|
|
|
#define TONEMAPPER_LINEAR 0
|
|
#define TONEMAPPER_REINHARD 1
|
|
#define TONEMAPPER_FILMIC 2
|
|
#define TONEMAPPER_ACES 3
|
|
|
|
vec3 apply_tonemapping(vec3 color, float p_white) { // inputs are LINEAR, always outputs clamped [0;1] color
|
|
// Ensure color values passed to tonemappers are positive.
|
|
// They can be negative in the case of negative lights, which leads to undesired behavior.
|
|
if (tonemapper == TONEMAPPER_LINEAR) {
|
|
return color;
|
|
} else if (tonemapper == TONEMAPPER_REINHARD) {
|
|
return tonemap_reinhard(max(vec3(0.0f), color), p_white);
|
|
} else if (tonemapper == TONEMAPPER_FILMIC) {
|
|
return tonemap_filmic(max(vec3(0.0f), color), p_white);
|
|
} else { // TONEMAPPER_ACES
|
|
return tonemap_aces(max(vec3(0.0f), color), p_white);
|
|
}
|
|
}
|