mirror of
https://github.com/godotengine/godot
synced 2024-11-02 08:53:46 +00:00
7e0f7d3abd
Not everything is yet implemented, either for Godot or personal limitations (I don't have all hardware in the world). A brief list of the most important issues follows: - Single-window only: the `DisplayServer` API doesn't expose enough information for properly creating XDG shell windows. - Very dumb rendering loop: this is very complicated, just know that the low consumption mode is forced to 2000 Hz and some clever hacks are in place to overcome a specific Wayland limitation. This will be improved to the extent possible both downstream and upstream. - Features to implement yet: IME, touch input, native file dialog, drawing tablet (commented out due to a refactor), screen recording. - Mouse passthrough can't be implement through a poly API, we need a rect-based one. - The cursor doesn't yet support fractional scaling. - Auto scale is rounded up when using fractional scaling as we don't have a per-window scale query API (basically we need `DisplayServer::window_get_scale`). - Building with `x11=no wayland=yes opengl=yes openxr=yes` fails. This also adds a new project property and editor setting for selecting the default DisplayServer to start, to allow this backend to start first in exported projects (X11 is still the default for now). The editor setting always overrides the project setting. Special thanks to Drew Devault, toger5, Sebastian Krzyszkowiak, Leandro Benedet Garcia, Subhransu, Yury Zhuravlev and Mara Huldra.
64 lines
2.2 KiB
Python
64 lines
2.2 KiB
Python
#!/usr/bin/env python
|
|
|
|
Import("env")
|
|
|
|
thirdparty_obj = []
|
|
thirdparty_dir = "#thirdparty/vulkan"
|
|
thirdparty_volk_dir = "#thirdparty/volk"
|
|
|
|
# Use bundled Vulkan headers
|
|
env.Prepend(CPPPATH=[thirdparty_dir, thirdparty_dir + "/include"])
|
|
|
|
if env["use_volk"]:
|
|
env.AppendUnique(CPPDEFINES=["USE_VOLK"])
|
|
env.Prepend(CPPPATH=[thirdparty_volk_dir])
|
|
|
|
if env["platform"] == "android":
|
|
env.AppendUnique(CPPDEFINES=["VK_USE_PLATFORM_ANDROID_KHR"])
|
|
elif env["platform"] == "ios":
|
|
env.AppendUnique(CPPDEFINES=["VK_USE_PLATFORM_IOS_MVK"])
|
|
elif env["platform"] == "linuxbsd":
|
|
if env["x11"]:
|
|
env.AppendUnique(CPPDEFINES=["VK_USE_PLATFORM_XLIB_KHR"])
|
|
if env["wayland"]:
|
|
env.AppendUnique(CPPDEFINES=["VK_USE_PLATFORM_WAYLAND_KHR"])
|
|
elif env["platform"] == "macos":
|
|
env.AppendUnique(CPPDEFINES=["VK_USE_PLATFORM_MACOS_MVK"])
|
|
elif env["platform"] == "windows":
|
|
env.AppendUnique(CPPDEFINES=["VK_USE_PLATFORM_WIN32_KHR"])
|
|
|
|
# Build Vulkan memory allocator and volk
|
|
env_thirdparty_vma = env.Clone()
|
|
env_thirdparty_vma.disable_warnings()
|
|
thirdparty_sources_vma = [thirdparty_dir + "/vk_mem_alloc.cpp"]
|
|
|
|
if env["use_volk"]:
|
|
env_thirdparty_vma.AppendUnique(CPPDEFINES=["VMA_STATIC_VULKAN_FUNCTIONS=1"])
|
|
env_thirdparty_volk = env.Clone()
|
|
env_thirdparty_volk.disable_warnings()
|
|
|
|
thirdparty_sources_volk = [thirdparty_volk_dir + "/volk.c"]
|
|
env_thirdparty_volk.add_source_files(thirdparty_obj, thirdparty_sources_volk)
|
|
elif env["platform"] == "android":
|
|
# Our current NDK version only provides old Vulkan headers,
|
|
# so we have to limit VMA.
|
|
env_thirdparty_vma.AppendUnique(CPPDEFINES=["VMA_VULKAN_VERSION=1000000"])
|
|
elif env["platform"] == "macos" or env["platform"] == "ios":
|
|
# MoltenVK supports only Vulkan 1.1 API, limit VMA to the same version.
|
|
env_thirdparty_vma.AppendUnique(CPPDEFINES=["VMA_VULKAN_VERSION=1001000"])
|
|
|
|
env_thirdparty_vma.add_source_files(thirdparty_obj, thirdparty_sources_vma)
|
|
|
|
|
|
env.drivers_sources += thirdparty_obj
|
|
|
|
|
|
# Godot source files
|
|
|
|
driver_obj = []
|
|
|
|
env.add_source_files(driver_obj, "*.cpp")
|
|
env.drivers_sources += driver_obj
|
|
|
|
# Needed to force rebuilding the driver files when the thirdparty code is updated.
|
|
env.Depends(driver_obj, thirdparty_obj)
|