mirror of
https://github.com/git/git
synced 2024-08-28 12:09:19 +00:00
![Ævar Arnfjörð Bjarmason](/assets/img/avatar_default.png)
Before my 20d2a30f8f
("Makefile: replace perl/Makefile.PL with simple
make rules", 2017-12-10) on an OS package that removed the
private-Error.pm copy we carried around manually removing the OS's
Error.pm would yield:
$ git add -p
Can't locate Error.pm in @INC (you may need to install the Error module) [...]
Now, before this change we'll instead emit this more cryptic error:
$ git add -p
BUG: '/usr/share/perl5/Git/FromCPAN' should be a directory! at /usr/share/perl5/Git/Error.pm line 36.
This is a confusing error. Now if the new NO_PERL_CPAN_FALLBACKS
option is specified and we can't find the module we'll instead emit:
$ /tmp/git/bin/git add -p
BUG: The 'Error' module is not here, but NO_PERL_CPAN_FALLBACKS was set!
[...]
Where [...] is the lengthy explanation seen in the change below, which
explains what the potential breakage is, and how to fix it.
The reason for checking @@NO_PERL_CPAN_FALLBACKS@@] against the empty
string in Perl is as opposed to checking for a boolean value is that
that's (as far as I can tell) make's idea of a string that's set, and
e.g. NO_PERL_CPAN_FALLBACKS=0 is enough to set NO_PERL_CPAN_FALLBACKS.
Signed-off-by: Ævar Arnfjörð Bjarmason <avarab@gmail.com>
Signed-off-by: Junio C Hamano <gitster@pobox.com>
105 lines
3.4 KiB
Perl
105 lines
3.4 KiB
Perl
package Git::LoadCPAN;
|
|
use 5.008;
|
|
use strict;
|
|
use warnings;
|
|
|
|
=head1 NAME
|
|
|
|
Git::LoadCPAN - Wrapper for loading modules from the CPAN (OS) or Git's own copy
|
|
|
|
=head1 DESCRIPTION
|
|
|
|
The Perl code in Git depends on some modules from the CPAN, but we
|
|
don't want to make those a hard requirement for anyone building from
|
|
source.
|
|
|
|
Therefore the L<Git::LoadCPAN> namespace shipped with Git contains
|
|
wrapper modules like C<Git::LoadCPAN::Module::Name> that will first
|
|
attempt to load C<Module::Name> from the OS, and if that doesn't work
|
|
will fall back on C<FromCPAN::Module::Name> shipped with Git itself.
|
|
|
|
Usually distributors will not ship with Git's Git::FromCPAN tree at
|
|
all via the C<NO_PERL_CPAN_FALLBACKS> option, preferring to use their
|
|
own packaging of CPAN modules instead.
|
|
|
|
This module is only intended to be used for code shipping in the
|
|
C<git.git> repository. Use it for anything else at your peril!
|
|
|
|
=cut
|
|
|
|
# NO_PERL_CPAN_FALLBACKS_STR evades the sed search-replace from the
|
|
# Makefile, and allows for detecting whether the module is loaded from
|
|
# perl/Git as opposed to perl/build/Git, which is useful for one-off
|
|
# testing without having Error.pm et al installed.
|
|
use constant NO_PERL_CPAN_FALLBACKS_STR => '@@' . 'NO_PERL_CPAN_FALLBACKS' . '@@';
|
|
use constant NO_PERL_CPAN_FALLBACKS => (
|
|
q[@@NO_PERL_CPAN_FALLBACKS@@] ne ''
|
|
and
|
|
q[@@NO_PERL_CPAN_FALLBACKS@@] ne NO_PERL_CPAN_FALLBACKS_STR
|
|
);
|
|
|
|
sub import {
|
|
shift;
|
|
my $caller = caller;
|
|
my %args = @_;
|
|
my $module = exists $args{module} ? delete $args{module} : die "BUG: Expected 'module' parameter!";
|
|
my $import = exists $args{import} ? delete $args{import} : die "BUG: Expected 'import' parameter!";
|
|
die "BUG: Too many arguments!" if keys %args;
|
|
|
|
# Foo::Bar to Foo/Bar.pm
|
|
my $package_pm = $module;
|
|
$package_pm =~ s[::][/]g;
|
|
$package_pm .= '.pm';
|
|
|
|
eval {
|
|
require $package_pm;
|
|
1;
|
|
} or do {
|
|
my $error = $@ || "Zombie Error";
|
|
|
|
if (NO_PERL_CPAN_FALLBACKS) {
|
|
chomp(my $error = sprintf <<'THEY_PROMISED', $module);
|
|
BUG: The '%s' module is not here, but NO_PERL_CPAN_FALLBACKS was set!
|
|
|
|
Git needs this Perl module from the CPAN, and will by default ship
|
|
with a copy of it. This Git was built with NO_PERL_CPAN_FALLBACKS,
|
|
meaning that whoever built it promised to provide this module.
|
|
|
|
You're seeing this error because they broke that promise, and we can't
|
|
load our fallback version, since we were asked not to install it.
|
|
|
|
If you're seeing this error and didn't package Git yourself the
|
|
package you're using is broken, or your system is broken. This error
|
|
won't appear if Git is built without NO_PERL_CPAN_FALLBACKS (instead
|
|
we'll use our fallback version of the module).
|
|
THEY_PROMISED
|
|
die $error;
|
|
}
|
|
|
|
my $Git_LoadCPAN_pm_path = $INC{"Git/LoadCPAN.pm"} || die "BUG: Should have our own path from %INC!";
|
|
|
|
require File::Basename;
|
|
my $Git_LoadCPAN_pm_root = File::Basename::dirname($Git_LoadCPAN_pm_path) || die "BUG: Can't figure out lib/Git dirname from '$Git_LoadCPAN_pm_path'!";
|
|
|
|
require File::Spec;
|
|
my $Git_pm_FromCPAN_root = File::Spec->catdir($Git_LoadCPAN_pm_root, '..', 'FromCPAN');
|
|
die "BUG: '$Git_pm_FromCPAN_root' should be a directory!" unless -d $Git_pm_FromCPAN_root;
|
|
|
|
local @INC = ($Git_pm_FromCPAN_root, @INC);
|
|
require $package_pm;
|
|
};
|
|
|
|
if ($import) {
|
|
no strict 'refs';
|
|
*{"${caller}::import"} = sub {
|
|
shift;
|
|
use strict 'refs';
|
|
unshift @_, $module;
|
|
goto &{"${module}::import"};
|
|
};
|
|
use strict 'refs';
|
|
}
|
|
}
|
|
|
|
1;
|