mirror of
https://github.com/git/git
synced 2024-09-12 21:04:12 +00:00
2a59a6ef20
The "head -c BYTES" option is non-portable (not in POSIX[1]). Change such invocations to use the test_copy_bytes wrapper added in48860819e8
("t9300: factor out portable "head -c" replacement", 2016-06-30). This fixes a test added in9d2e330b17
("ewah_read_mmap: bounds-check mmap reads", 2018-06-14), which has been breaking t5310-pack-bitmaps.sh on OpenBSD since 2.18.0. The OpenBSD ports already have a similar workaround after their upgrade to 2.18.0[2]. I have not tested this on IRIX, but according to4de0bbd898
("t9300: use perl "head -c" clone in place of "dd bs=1 count=16000" kluge", 2010-12-13) this invocation would have broken things there too. Also, change a valgrind-specific codepath in test-lib.sh to use this wrapper. Given where valgrind runs I don't think this would ever become a portability issue in practice, but it's easier to just use the wrapper than introduce some exception for the "make test-lint" check being added here. 1. http://pubs.opengroup.org/onlinepubs/9699919799/utilities/head.html 2.08d5d82eae (diff-f7d3c4fabeed1691620d608f1534f5e5)
Signed-off-by: Ævar Arnfjörð Bjarmason <avarab@gmail.com> Signed-off-by: Junio C Hamano <gitster@pobox.com>
52 lines
1.4 KiB
Perl
Executable file
52 lines
1.4 KiB
Perl
Executable file
#!/usr/bin/perl
|
|
|
|
# Test t0000..t9999.sh for non portable shell scripts
|
|
# This script can be called with one or more filenames as parameters
|
|
|
|
use strict;
|
|
use warnings;
|
|
|
|
my $exit_code=0;
|
|
my %func;
|
|
|
|
sub err {
|
|
my $msg = shift;
|
|
s/^\s+//;
|
|
s/\s+$//;
|
|
s/\s+/ /g;
|
|
print "$ARGV:$.: error: $msg: $_\n";
|
|
$exit_code = 1;
|
|
}
|
|
|
|
# glean names of shell functions
|
|
for my $i (@ARGV) {
|
|
open(my $f, '<', $i) or die "$0: $i: $!\n";
|
|
while (<$f>) {
|
|
$func{$1} = 1 if /^\s*(\w+)\s*\(\)\s*{\s*$/;
|
|
}
|
|
close $f;
|
|
}
|
|
|
|
while (<>) {
|
|
chomp;
|
|
# stitch together incomplete lines (those ending with "\")
|
|
while (s/\\$//) {
|
|
$_ .= readline;
|
|
chomp;
|
|
}
|
|
|
|
/\bsed\s+-i/ and err 'sed -i is not portable';
|
|
/\becho\s+-[neE]/ and err 'echo with option is not portable (use printf)';
|
|
/^\s*declare\s+/ and err 'arrays/declare not portable';
|
|
/^\s*[^#]\s*which\s/ and err 'which is not portable (use type)';
|
|
/\btest\s+[^=]*==/ and err '"test a == b" is not portable (use =)';
|
|
/\bwc -l.*"\s*=/ and err '`"$(wc -l)"` is not portable (use test_line_count)';
|
|
/\bhead\s+-c\b/ and err 'head -c is not portable (use test_copy_bytes BYTES <file >out)';
|
|
/\bexport\s+[A-Za-z0-9_]*=/ and err '"export FOO=bar" is not portable (use FOO=bar && export FOO)';
|
|
/^\s*([A-Z0-9_]+=(\w+|(["']).*?\3)\s+)+(\w+)/ and exists($func{$4}) and
|
|
err '"FOO=bar shell_func" assignment extends beyond "shell_func"';
|
|
# this resets our $. for each file
|
|
close ARGV if eof;
|
|
}
|
|
exit $exit_code;
|